2 způsoby tisku seznamů úkolů aplikace Outlook s různými kategoriemi na různých stránkách

Pokud jste svým úkolům aplikace Outlook přiřadili různé barevné kategorie a nyní chcete vytisknout seznamy úkolů s různými kategoriemi na různých stránkách, můžete si přečíst tento článek. Zde se s vámi podělíme o 2 způsoby, jak to získat.

Abyste mohli své úkoly klasifikovat a dobře spravovat, možná jste na své úkoly použili barevné kategorie. Nyní, pokud byste si chtěli vytisknout seznamy vašich úkolů s různými kategoriemi na různých stránkách, čtěte dále. V následujícím textu vám představíme 2 způsoby, jak to získat.

Metoda 1: Ruční tisk seznamů úkolů jeden po druhém

1. Nejprve v aplikaci Outlook otevřete panel „Úkoly“.
2. Poté otevřete složku Úkol.
3. Poté stiskněte "Ctrl + E" pro aktivaci pásu "Hledat".
4. Poté na kartě „Hledat“ klikněte na tlačítko „Kategorizovat“.
5. Z rozevíracího seznamu vyberte kategorii barev.
6. Poté v seznamu zůstanou pouze úkoly s vybranou kategorií.
7. Nyní přejděte na „Soubor“ > „Tisk“ a vytiskněte tento seznam úkolů.
8. Následně stejným způsobem vytiskněte seznamy úkolů s ostatními barevnými kategoriemi jeden po druhém ručně.

Metoda 2: Dávkový tisk seznamů úkolů pomocí jazyka VBA

1. Na úplném začátku spusťte editor VBA v souladu s „Jak spustit kód VBA ve vašem Outlooku".
2. Poté přidejte odkaz na „Knihovnu objektů MS Excel“ dle pokynů „Jak přidat odkaz na knihovnu objektů ve VBA".
3. Dále zkopírujte následující kód VBA do modulu.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Poté stiskněte klávesu „F5“ pro okamžité spuštění tohoto makra.
5. Po dokončení makra se seznamy úkolů s různými kategoriemi vytisknou na různé stránky, jak ukazuje následující snímek obrazovky.

Získejte zpět cenná data z kompromitovaného souboru PST

Pokud podléháte nepřístupnému souboru PST, váš další krok je nepochybně Oprava PST. V takovém případě můžete nejprve vyzkoušet nástroj na opravu doručené pošty. Pokud selže, můžete přistoupit k vyzkoušení jiného externího nástroje, např DataNumen Outlook Repair. Je schopen obnovit data PST v rychlém čase.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně obnovit mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com