2 metody rychlého odeslání vybraných buněk v listu aplikace Excel jako e-mail aplikace Outlook

Někdy můžete chtít rychle vložit vybrané buňky v listu aplikace Excel do e-mailu aplikace Outlook a odeslat tento e-mail. Tento článek se podívá na toto přání a nabídne vám 2 způsoby.

Můj předchozí článek “2 rychlé metody pro odeslání listu aplikace Excel jako e-mailu aplikace Outlook“ vás naučil, jak poslat celý excelový list jako e-mail. Někdy však chcete odeslat pouze vybrané buňky v listu jako e-mail. V reakci na tento požadavek vám zde ukážeme 2 způsoby. Můžete si vybrat buď podle svých preferencí.

Metoda 1: Zkopírujte vybrané buňky do e-mailu ručně

1. Nejprve otevřete zdrojový soubor aplikace Excel a získejte přístup k správnému listu aplikace Excel.
2. Poté vyberte buňky, které chcete odeslat jako e-mail aplikace Outlook.
3. Poté stiskněte klávesové zkratky "Ctrl + C" pro zkopírování vybraných buněk.
4. Poté spusťte aplikaci Outlook.
5. Následně klikněte na tlačítko „Nový e-mail“ na pásu karet „Domů“ a vytvořte nový e-mail Outlook.
6. Později v novém okně Zpráva klikněte do části těla zprávy.
7. Poté stisknutím kláves „Ctrl + V“ vložte dříve zkopírované vybrané buňky aplikace Excel.
8. Nakonec můžete napsat e-mail jako obvykle a kliknutím na tlačítko „Odeslat“ jej odeslat.

Metoda 2: Odešlete vybrané buňky jako e-mail přes VBA

1. Na úplném začátku otevřete zdrojový sešit Excel.
2. Poté stisknutím kláves „Alt + F11“ otevřete editor Excel VBA.
3. V novém okně klikněte na „Vložit“ > „Modul“ pro vložení nového modulu.
4. Dále byste měli povolit objekty Microsoft Outlook. Klikněte na „Nástroje“ > „Odkazy“. V rozbalovacím dialogovém okně vyhledejte a zaškrtněte „Knihovna objektů Microsoft Outlook“.
5. Následně zkopírujte následující kód VBA do tohoto modulu.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Nakonec to můžete vyzkoušet.

• Nejprve vyberte konkrétní buňky jako obvykle.
• Poté se vraťte k novému makru a stisknutím klávesy F5 jej spusťte.
• Okamžitě se zobrazí nový e-mail aplikace Outlook, ve kterém můžete vidět, že vybrané buňky byly vloženy do těla e-mailu, jako je následující snímek obrazovky:

Soubor PST je stejně zranitelný jako soubor Excel

Jak víme, soubory Excelu a Wordu jsou náchylné k poškození. Totéž platí pro soubor PST, který obsahuje všechny položky ve vaší poštovní schránce Outlooku. Zabezpečení dat PST je tedy náročný úkol. Jedním z nejúčinnějších opatření je pravidelné zálohování souboru. Navíc, abyste zajistili okamžitou záchranu, měli byste si připravit zkušený nástroj, jako například DataNumen Outlook Repair, který je schopen obnovit Outlook data bez potu.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně opravit mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com