Kako automatski koristiti različite boje fonta za odgovaranje i prosljeđivanje e-pošte s Outlook VBA

Prema zadanim postavkama, ne možete dozvoliti da Outlook automatski koristi različite boje fonta za odgovaranje i prosljeđivanje e-poruka. Stoga, ako imate takav zahtjev, možete pročitati ovu strost naučiti pametan pristup.

Outlook vam dozvoljava samo da navedete font koji se koristi i za odgovaranje i za prosljeđivanje e-pošte. Možete ići na “Datoteka” > “Opcije”. Zatim, u "Opcijama Outlooka", okrenite se na karticu "Pošta" i kliknite na dugme "Dopisnica i fontovi...". U sljedećem prozoru možete vidjeti dugme “Font” u “Odgovaranje ili prosljeđivanje poruka”. Kliknite na njega, a zatim možete postaviti određenu boju fonta za odgovaranje i prosljeđivanje e-poruka.

Međutim, mnogi korisnici se nadaju da će koristiti različite boje fonta za odgovaranje ili prosljeđivanje e-pošte. Iako Outlook ne pruža nikakve direktne funkcije za ovo, ipak se može realizovati pomoću VBA koda. Sada, čitajte dalje da biste dobili takav komad VBA koda.

Automatski koristite različite boje fonta za odgovaranje i prosljeđivanje e-pošte

1. Za astart, pokrenite Outlook aplikaciju.
2. Zatim pokrenite VBA editor sa referencom na “Kako pokrenuti VBA kod u vašem Outlooku".
3. Zatim, u skladu sa „Kako dodati Object Library Referenca u VBA“, dodajte referencu na „MS Word Object LibrarY".
4. Nakon toga, kopirajte sljedeći kod u projekt “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Nakon toga, reztart Outlook da aktivirate ovaj makro.
6. Konačno, možete probati.

• Odaberite ili otvorite e-poštu.
• Zatim kliknite na dugme „Odgovori“. Prilikom odgovaranja na e-poštu, možete upisati neke riječi u tijelo. Boja fonta mora biti ružičasta.
• Ili kliknite na dugme "Odgovori svima". U novoj poruci koja odgovara na sve, unesite riječi u tijelo. Boja fonta je sigurno zelena.
• Slično, kliknite na dugme „Naprijed“. U pošti za prosljeđivanje, nove riječi će biti prikazane plavom bojom.

Pribjegnite pouzdanom softveru

U slučaju Outlook korupcija, most korisnici obično pribjegavaju Outlook softveru za oporavak. Na tržištu postoji velika količina takvih programa. A neki od njih su čak i besplatni. Ipak, trebali biste se čuvati onih iz nepoznatih izvora jer mogu pogoršati trenutni slučaj. Trebali biste uzeti pomoć pouzdanog i iskusnog alata, npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen sql i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com