Kako automatski izbrisati Outlook e-poštu od određenog pošiljaoca nakon određenih dana

Da biste omogućili vašem Outlooku da automatski briše e-poruke određenog pošiljatelja iz određenih dana, možete pročitati ovaj članak. Ovdje ćemo vam pokazati detaljne korake za korištenje VBA koda da biste ga dobili.

Kada je u pitanju automatsko brisanje e-pošte, možda prvo pomislite na funkciju „AutoArchive“. Međutim, ne može filtrirati određene pošiljatelje prilikom automatskog arhiviranja e-pošte. Stoga, na primjer, ako želite automatski izbrisati e-poruke od određenog pošiljatelja nakon x dana, trebali biste koristiti druga sredstva, poput sljedećeg.

Automatsko brisanje e-poruka od određenog pošiljaoca nakon X dana

1. Na samom početku pokrenite Outlook aplikaciju.
2. Zatim pokrenite Outlook VBA editor prema “Kako pokrenuti VBA kod u vašem Outlooku".
3. Zatim kopirajte sljedeći VBA kod u projekt “ThisOutlookSession”.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Nakon toga, ponovo pokrenite Outlook da biste aktivirali ovaj makro.
5. Od tada, svaki put kada nova e-pošta od određenog pošiljaoca stigne u Inbox, biće joj dodeljeno određeno vreme isteka – određene dane nakon što je primljena.
6. Zatim, svaki put kada pokrenete Outlook, Outlook će automatski provjeriti i izbrisati istekle e-poruke od određenog pošiljatelja.

Vratite Outlook podatke nakon oštećenja

Možda ste naišli na razne greške i probleme u Outlooku. Zatim, jeste li se ikada suočili s korupcijom u Outlooku? Na primjer, ako često napuštate Outlook nepravilno, vaša PST datoteka ima tendenciju da se ošteti. Općenito, u takvom slučaju možete odabrati preuzimanje Outlook podataka iz rezervnih kopija. Ili možete koristiti alat za popravku inboxa ili pouzdan eksterni alat, kao npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti sql i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com