Outlook-da dublikatlar olmadan bir neçə qovluqdan elementləri necə tez birləşdirmək olar

Birdən çox Outlook qovluğundakı bütün elementləri birləşdirmək və dublikatın olmamasını təmin etmək istəyirsinizsə, bu məqalədə təqdim olunan üsuldan istifadə edə bilərsiniz. Bunu mantar kimi yerinə yetirməyə kömək etmək üçün VBA kodundan istifadə edir.

Bəzən bir neçə Outlook qovluğundakı elementləri birləşdirmək istəyə bilərsiniz, məsələn, bir neçə Outlook Əlaqə qovluğunun bütün kontaktlarını birləşdirmək. Bu vəziyyətdə, bu qovluqlar arasında təkrarlanan kontaktlar varsa, dublikatların birləşmə zamanı avtomatik olaraq silinə biləcəyinə ümid etməlisiniz. Bu vəziyyətdə, asanlıqla həyata keçirmək üçün aşağıdakı VBA kodundan istifadə edə bilərsiniz.

Bir neçə qovluqdan elementləri dublikatsız birləşdirin

1. Starilə Outlook proqramınızı işə salın.
2. Sonra, Outlook-un əsas ekranındakı “Alt + F11” düyməsinə basaraq Outlook VBA redaktoruna daxil olmalısınız.
3. Sonra, "Proqramlar üçün Microsoft Visual Basic" pəncərəsində istifadə olunmayan modulu açmalısınız.
4. Bundan sonra aşağıdakı VBA kodunu bu modula köçürməlisiniz.

'Here we take "merging two folders" as an example
Sub MergeOutlookFolders_WithoutDuplicates()
    Dim objSourceFolder As Outlook.Folder
    Dim objTargetFolder As Outlook.Folder
    Dim i, n, x As Long
    Dim objItem As Object
    Dim objDictionary As Object
    Dim strKey As String
 
    Set objSourceFolder = Application.Session.PickFolder
    Set objTargetFolder = Application.Session.PickFolder

    If objSourceFolder.DefaultItemType <> objTargetFolder.DefaultItemType Then
       MsgBox "Error: The two folders are not in same type!", vbExclamation + vbOKOnly
    Else
       'Merge the two folders
       For i = objSourceFolder.Items.count To 1 Step -1
           Set objItem = objSourceFolder.Items.Item(i)
           objItem.Move objTargetFolder
       Next i
 
       Set objDictionary = CreateObject("scripting.dictionary")
 
       'Remove the duplicates
       x = 0
       For n = objTargetFolder.Items.count To 1 Step -1
           Set objItem = objTargetFolder.Items.Item(n)
 
           Select Case objItem.Class
                  Case olMail
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  Case olAppointment
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  Case olContact
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  Case olTask
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
              x = x + 1
           Else
              objDictionary.Add strKey, True
           End If
      Next n
 
      'Prompt you of the count of removed duplicates
      If x <> 0 Then
         MsgBox x & " duplicates removed when merging!", vbInformation + vbOKOnly
      End If
    End If
End Sub

5. Daha sonra makronun aktiv olduğundan əmin olmaq üçün Outlook makro parametrlərinizi yoxlamaq lazımdır.
6. Nəhayət, bir cəhd edə bilərsiniz.

• Əvvəlcə yeni modul pəncərəsinə qayıdın.
• Sonra bu makronu işə salmaq üçün F5 düyməsini sıxın.
• Sonra birləşdiriləcək iki qovluğu seçməlisiniz. Birincisi mənbədir, ikincisi isə tarbirini əldə etmək.
• Bundan sonra, Outlook bütün elementləri mənbə qovluğundan qovluğa köçürməyə başlayacaq tarbirini əldə etmək. Həmçinin, bu vaxt dublikatlar avtomatik silinəcək.
• Nəhayət, aşağıdakı skrinşot kimi silinmiş dublikatların sayını göstərən bir mesaj ala bilərsiniz:

Kiçik Səhvlər Böyük Qəzalara səbəb ola bilər

Çoxlu sayda əla funksiyalarla yüklənməsinə baxmayaraq, Outlook hələ də səhvlərə və korrupsiyaya həssasdır. Yəqin ki, müxtəlif Outlook problemləri ilə qarşılaşmısınız. Bir çox istifadəçi təsadüfi səhvlərə məhəl qoymamağa meyllidir. Bununla belə, Outlook faylını təhlükə altına alan ciddi Outlook qəzalarına səbəb olan kiçik səhvdir. Beləliklə, kiçik səhvləri nəzərə almamalısınız. Əksinə, onları mümkün qədər tez aradan qaldırmalısınız. Bundan əlavə, bir mənzil saxlamağınız daha yaxşıdır PST təmiri kimi alət DataNumen Outlook Repair. Yüksək bərpa sürəti sayəsində bu yardım proqramı həmyaşıdlarını üstələyib.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş sql və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com