Səsvermə statistikasını Outlook e-poçtundan Excel iş vərəqinə necə tez ixrac etmək olar

Səsvermə düymələri olan bir e-poçt göndərmisinizsə, alıcılar sizə cavablarını göndərdikdən sonra səsvermə statistikasını saymaq və Excel iş vərəqinə ixrac etmək istəyə bilərsiniz. Beləliklə, bu yazıda sizə bunu necə tez bir zamanda edəcəyinizi öyrədəcəyik.

Outlook o qədər güclüdür ki, hətta "Səsvermə" funksiyasını da təklif edir. Əvvəlki məqaləm “Səsvermə üçün MS Outlook-dan bacarıqla istifadə"bundan necə səmərəli istifadə edəcəyinizi öyrətdi. Həmçinin, əksər hallarda səs verdikdən sonra, statistikanı çap etmək kimi bəzi səbəblərə görə səsvermə statistikasını Excel iş vərəqinə ixrac edə bilərsiniz. Lakin Outlook bunu standart olaraq dəstəkləmir. Beləliklə, aşağıda sizə bunu necə edəcəyinizi öyrədəcəyik.

E-poçtdakı Səsvermə Statistikasını Excel İş Vərəqinə ixrac edin

1. Ən başlanğıcda Outlook proqramınızı işə salın.
2. Sonra əsas Outlook pəncərəsində "Alt + F11" düymələrini basmalısınız.
3. Növbəti olaraq, "Microsoft Visual Basic for Applications" pəncərəsində "Microsoft Excel Obyekt Kitabxanası"nı aktivləşdirməlisiniz. "Alətlər" > "İstinad" düymələrini basın. Daha sonra açılan informasiya qutusunda "Microsoft Excel Obyekt Kitabxanası"nın qarşısındakı onay qutusunu işarələyin və sonda "OK" düyməsini basın.
4. Bundan sonra siz yeni modul daxil edə və ya istifadə olunmayan modulu aça bilərsiniz.
5. Sonradan aşağıdakı VBA kodlarını kopyalayıb bu modula yapışdırın.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Bundan sonra, rahat giriş üçün Sürətli Giriş Alətlər Panelinə yeni makro əlavə etmək daha yaxşıdır.
6. Nəhayət, bir cəhd edə bilərsiniz.

• Əvvəlcə səsvermə düymələri olan mənbə e-poçtunu seçin.
• Sonra Tez Giriş Alətlər Panelində makro düyməsini basın.
• Bu makronun işləməsi başa çatdıqdan sonra siz əvvəlcədən təyin edilmiş yerli qovluğa keçə bilərsiniz, orada yeni Excel iş kitabını görəcəksiniz.
• Bu Excel iş kitabını açın. İndi aşağıdakı şəkildə göstərilən səsvermə statistikasını görəcəksiniz:

Heç kim Outlook Səhvlərini Hərtərəfli Qarşıya Verə bilməz

Outlook müxtəlif imkanlarla təchiz edilsə də, Outlook səhvlərindən qaçmağa kömək edəcək belə bir xüsusiyyət yoxdur. Bütün növ amillər Outlook səhvlərinə səbəb ola bilər. Məsələn, Outlook-dan tez-tez düzgün çıxsanız, əziyyət çəkəcəksiniz PST korrupsiyası. Belə bir ssenaridə PST faylınızı xilas etmək üçün bəzi güclü vasitələrdən istifadə etməkdən başqa seçiminiz yoxdur. DataNumen Outlook Repair. Yüksək bərpa sürətinə görə çoxlu təriflər qazandı.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc pozulmuş mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com