Birdən çox Outlook e-poçtlarını VBA vasitəsilə bir Word sənədinə toplu şəkildə necə ixrac etmək olar

Birdən çox Outlook e-poçtunu bir söz sənədinə toplu şəkildə ixrac etmək istəyirsinizsə, bu məqalədə göstərilən VBA kodundan istifadə edə bilərsiniz. Bu tapşırığı saniyələr ərzində yerinə yetirməkdə sizə kömək edə bilər.

Mən əvvəlki məqaləmdə Outlook e-poçtunu Word sənədinə necə çevirməyi təqdim etmişəm – “Outlook E-poçtunu Word sənədinə çevirməyin 2 Effektiv Metodları”. Bununla belə, həmin s-də qeyd olunan hər iki vasitəost çoxlu e-poçtları bir Word sənədinə toplu şəkildə ixrac etmək istədiyiniz halda çarəsiz qalacaqsınız. Beləliklə, burada sizə başqa bir yol öyrədəcəyik. İndi ətraflı öyrənmək üçün oxuyun.

Bir Word Sənədinə Çoxlu Outlook E-poçtlarını Toplu İxrac edin

1. Starilə Outlook proqramınızı işə salın.
2. Sonra əsas Outlook pəncərəsinə daxil olduqdan sonra “Alt + F11” düymələrini sıxmalısınız.
3. Sonra boş modulu açmalı olduğunuz Outlook VBA redaktoruna giriş əldə edəcəksiniz.
4. Sonra, açılmış modul pəncərəsinə aşağıdakı VBA kodunu kopyalayın.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Bundan sonra, bu yeni VBA layihəsini Tez Giriş Alətlər Panelinə və ya lentə əlavə etmək daha yaxşıdır.
6. Nəhayət, cəhd edə bilərsiniz.

• İlk növbədə, birdən çox Outlook e-poçtunu seçin.
• Sonra tapın və yeni əlavə edilmiş makro düyməsini basın.
• Sizdən “Tamamlandı” tələb edildikdən sonra yeni Word sənədini tapmaq üçün əvvəlcədən təyin edilmiş yerli qovluğa baxa bilərsiniz.
• Bütün seçilmiş e-poçtların ixrac edildiyini görə biləcəyiniz bu sənədi açın.

Yaxınlıqda Güclü Bərpa Alətini saxlayın

Çoxsaylı funksiyalardan asılı olmayaraq, Outlook hələ də səhvlərdən immun ola bilməz. Səhvləri tək buraxmağa öyrəşmisinizsə, onların yığılması ilə Outlook qəzası mütləq baş verəcək. Bu nöqtədə, kimi güclü və təsirli bir bərpa vasitəsinə müraciət etmək vacibdir DataNumen Outlook Repair. Bunu yaxşı bilir PST düzəlişi. Bununla birlikdə, bir daha dünyagörüşü məlumatlarının itirilməsindən narahat olmayacaqsınız.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com