a-nın xüsusi slaydlarını necə tez əlavə etmək olar PowerPoint Outlook E-poçtunuza təqdimat

Xüsusi slaydları çıxarmaq istəyirsinizsə, a PowerPoint təqdimatı ayrıca yeni təqdimata əlavə edin və onu Outlook e-poçtuna əlavə edin, bu məqalədə paylaşılan üsuldan istifadə edə bilərsiniz.

Bütün əlavə etmək əvəzinə PowerPoint təqdimatı e-poçta göndərmək, əgər siz təqdimatın xüsusi slaydlarını əlavə etmək istəyirsinizsə, ümumiyyətlə, əvvəlcə xüsusi slaydları yeni təqdimata köçürməlisiniz. Çox əziyyətlidir. Buna görə də, burada sizə bir anda həyata keçirə biləcək bir üsul göstərəcəyik.

a-nın Xüsusi Slaydlarını əlavə edin PowerPoint E-poçta təqdimat

1. Əvvəlcə spesifikliyi açın PowerPoint təqdimat.
2. Sonra, PowerPoint proqram pəncərəsində VBA redaktoruna daxil olmaq üçün “Alt + F11” düymələrini basın.
3. Sonra, yeni pəncərədə “Daxil et” > “Modul” düyməsini basaraq yeni modul yaradın.
4. Sonradan aşağıdakı VBA kodunu kopyalayıb bu modula yapışdırın.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Bundan sonra cari pəncərəni bağlaya bilərsiniz.
6. Daha sonra, Tez Giriş Alətlər Panelinə yeni makro əlavə etmək üçün “Fayl” > “Seçimlər” > “Tez Giriş Alətlər Paneli”nə keçin.
7. Nəhayət, bu makronu sınaya bilərsiniz.

• Başlamaq üçün çıxarmaq istədiyiniz xüsusi slaydları seçin.
• Sonra, Tez Giriş Alətlər Panelində makro düyməsini basın.
• Dərhal bir Outlook e-poçtu görünəcək, orada bir PowerPoint mənbə təqdimatdan çıxarılan təqdimat.

Effektiv Bərpa Alətindən istifadə edin

Hamımızın bildiyimiz kimi, Outlook daxili təmir proqramı ilə təchiz edilmişdir - scanpst. Bununla belə, o, sadəcə Outlook-da kiçik qüsurların öhdəsindən gələ bilər. Qarşılaşdığınız şey ciddi zərərdirsə, təsir göstərməyəcəkdir. Bu zaman başqa bir güclü və etibarlı təmir alətinə müraciət etməkdən başqa seçiminiz yoxdur DataNumen Outlook Repair. Bununla siz zədələnmiş Outlook faylınızı xilas edə biləcəksiniz.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com