Bütün e-poçt ünvanlarını müəyyən bir domeni olan Outlook kontaktlarınızdan toplu şəkildə necə silmək olar

Bəzən müəyyən bir domeni olan bütün e-poçt ünvanlarını kontaktlarınızdan silməyi ümid edə bilərsiniz. Bu vəziyyətdə, bunu bir-bir etmək istəməməlisiniz. Beləliklə, bu səhost sizə daha ağıllı bir üsul öyrədəcək.

Məsələn, bir şirkət öz adını dəyişir. Eyni zamanda, şirkətin domeni də dəyişdirilir. Bununla belə, Outlook-da siz bu şirkətdə e-poçt ünvanları köhnə domendə olan bir çox əlaqə saxlamısınız. Təbii ki, bu e-poçt ünvanları artıq etibarlı deyil. Beləliklə, bu vəziyyətdə, bu e-poçt ünvanlarını bir anda silmək istəyirsinizsə, aşağıdakı üsuldan istifadə edə bilərsiniz.

Xüsusi Domeni olan Bütün E-poçt Ünvanlarını Kontaktlardan Toplu Silin

1. Kimi üçüntart, Outlook VBA redaktoruna "Alt + F11" qısayolu ilə daxil olun.
2. Sonra yeni pəncərədə aşağıdakı VBA kodunu boş modula yerləşdirin.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Bundan sonra kursoru “BatchRemoveAllEmailAddressesInSpecificDomain” alt proqramına qoyun.
4. Nəhayət, bu makronu işə salmaq üçün “F5” düyməsini sıxın.
5. Sonra, açılan informasiya qutusuna xüsusi domeni daxil edin.
6. "OK" düyməsini basdıqdan sonra makro işə düşəcək.
7. Bitirdikdə, nəticələr haqqında bir mesaj alacaqsınız.
8. İndi kontaktları yoxlaya bilərsiniz. Xüsusi domeni olan bütün e-poçt ünvanları yoxa çıxmalıdır.

Outlook faylınızı qoruyun

Outlook ilə bağlı getdikcə daha çox risk olduğundan, dəyərli Outlook məlumatlarınızı qorumaq getdikcə çətinləşir. Məsələn, yalnız məlumatların müntəzəm ehtiyat nüsxələrini çıxarmaqda davam etməli deyilsiniz, həm də əməliyyatlarınıza diqqət yetirməlisiniz. Naməlum göndəricilərdən gələn hər hansı bir e-poçta asanlıqla etibar etmək ağıllı deyil. Əks halda, o, virus daşıyırsa, Outlook faylınız yoluxmuş olacaq. Bu zaman cəhd etmək lazımdır Outlook təmiri kimi əlamətdar bir düzəltmə vasitəsi ilə DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc bərpa edin Sql Server və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com