Sənədinizdə Mətn Qutuları, Haşiyələr və Son Qeydlərlə Əlaqədar Söz Sayma Statistikası Almağın 3 Yolu

Bugünkü məqalədə, sənədinizdə mətn qutuları, alt qeydlər və son qeydlərlə əlaqəli söz sayı statistikasını əldə etməyin 3 sürətli yolu var.

Sənəddəki sözlərin ümumi sayını əldə etmək çətin deyil. Ancaq müxtəlif növ mətnlərin sözlərinin sayını əldə etmək istəyirsinizsə, daha çox əməliyyat tələb olunacaq. Aşağıda 3 üsul var. Nə istifadə edə biləcəyinizi öyrənmək üçün oxuyun. 

Metod 1: Mətn Qutularından, Haşiyələrdən və Son Qeydlərdən Mətnlər O cümlədən Sözləri Sayın

Varsayılan olaraq, Word sənəddə görünən bütün sözləri, o cümlədən mətn qutusundakı mətnləri, həmçinin qeyd və son qeydlərdən gələn sözləri hesablayır.

1. İlk növbədə, status çubuğuna keçin və "Sözlər" düyməsini basaraq "Sözlərin sayı" qutusunu açın.
2. Orada hər cür statistikanı görəcəksiniz. “Mətn qutularını, alt qeydləri və son qeydləri daxil edin” qutusunu işarələdiyinizə əmin olun.
3. Sonra "Bağla" düyməsini basın.
4. Əgər status panelində “Sözlər” əmrini tapa bilmirsinizsə, ora sağ klikləyin.
5. Sonra "Söz sayı"nı yoxlayın.

Metod 2: Mətnləri Mətn Qutularından, Haşiyələri və Son Qeydləri Söz Sayından Çıxarın

Bu, 1-ci üsula ziddir. Beləliklə, sadəcə olaraq “Mətn qutularını, alt qeydləri və son qeydləri daxil edin” qutusunun işarəsini silməlisiniz.

Metod 3: Mətn Qutularından, Haşiyələrdən və Son qeydlərdən ayrı-ayrı sözlərin sayını almaq üçün Word Makrosunu işlədin

1. Əvvəlcə 1-ci üsuldan istifadə edərək "Sözlərin sayı" qutusunu işə salın və seçim qutusunun işarələndiyinə əmin olun.
2. Sonra VBA redaktorunu açmaq üçün "Alt + F11" düyməsini basın.
3. Sonra əvvəlcə “Normal” düyməsini sıxaraq “Normal” layihəsində yeni modul daxil edin.
4. Və növbəti "Daxil et" düyməsini basın.
5. Sonra "Modul" seçin.
6. Kodlaşdırma sahəsini açmaq üçün modulun üzərinə iki dəfə klikləyin və ora aşağıdakı kodları yapışdırın:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Nəhayət, "Çalış" düyməsini basın.

Əgər mətn qutusu, alt qeyd və ya son qeyd yoxdursa, belə bir mesaj qutusu alacaqsınız:

Davam etmək üçün sadəcə "OK" düyməsini basın. Sonra söz sayının bütün təfərrüatlarını sadalayan başqa bir qutu görəcəksiniz.

Bərpa aləti alın

Word birdən-birə çökə bildiyi üçün düzəltmə işini yerinə yetirmək üçün qabaqcıl təmir məhsulu əldə etmək məsləhətdir. Belə bir vasitə əla qoruyucu ola bilər pozulmuş Word. Buna görə də, mümkün qədər tez birini əldə etmək üçün vaxt ayırın.

Müəllif Giriş:

Vera Çen məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc xls-i düzəldin və pdf proqram məhsullarının təmiri. Ətraflı məlumat üçün ziyarət edin www.datanumen.com