如何快速向未在 Outlook 中回复的人重新發送會議邀請

Outlook解決方案 2025 年 9 月 29 日
立即分享：

很多用戶都希望盡快將會議邀請重新發送給沒有做出任何回應的與會者。 本文將向您展示如何實現它。

在我上一篇文章中-“如何快速將通知郵件發送給未響應的會議參與者”，您可以了解如何向尚未回复的會議收件人發送通知郵件。 與此類似，許多用戶希望直接重新發送此會議邀請而不是通知郵件。 因此，下面我們將公開一段VBA代碼，可以幫助您瞬間實現。

快速向 Outlook 中未回复的人重新發送會議邀請

向尚未回复的人重新發送會議邀請

  1. 到tar然後啟動Outlook應用程序。
  2. 然後，在 Outlook 主窗口中，按“Alt + F11”鍵按鈕訪問 VBA 編輯器。
  3. 接下來，您應該打開一個未使用的模塊或簡單地插入一個新模塊。
  4. 隨後，將下面的 VBA 代碼複製並粘貼到此模塊中。
Sub ResendMeetingInvitationToAttendeesNotRespond()
    Dim objMeeting As AppointmentItem
    Dim objAttendees As Recipients
    Dim objAttendee As recipient
    Dim AttendeesNotRespond As String
    Dim objCopiedMeeting As AppointmentItem
    Dim objRecipient As recipient
    Dim objItem As Object
 
    Set objMeeting = ActiveExplorer.Selection.Item(1)
    'Create a copy of the source meeting
    Set objCopiedMeeting = objMeeting.Copy
 
    'Remove all the original recipients
    For i = objCopiedMeeting.Recipients.Count To 1 Step -1
        objCopiedMeeting.Recipients.Item(i).Delete
    Next
 
    Set objAttendees = objMeeting.Recipients
    For Each objAttendee In objAttendees
        If (objAttendee.Type <> olOrganizer) And (objAttendee.MeetingResponseStatus = olResponseNone) Then
           'Add the recipients who haven't responded to this meeting
           objCopiedMeeting.Recipients.Add (objAttendee.Address)
        End If
    Next
 
    'Send this copied meeting
    objCopiedMeeting.Recipients.ResolveAll
    objCopiedMeeting.Send
 
    'Permanently delete the copied meeting
    objCopiedMeeting.UserProperties.Add ("Clear"), olText
    objCopiedMeeting.Save
    objCopiedMeeting.Delete
    For Each objItem In Application.Session.GetDefaultFolder(olFolderDeletedItems).Items
        If TypeName(objItem.UserProperties.Find("Clear")) <> "Nothing" Then
           objItem.Delete
        End If
    Next
End Sub

VBA 代碼 - 快速向尚未回复的人重新發送會議邀請

  1. 之後，為了以後方便訪問，最好像往常一樣將這個新的 VBA 項目添加到快速訪問工具欄。
  2. 此外，訪問宏設置以確保允許使用宏。
  3. 最後，您可以嘗試一下：
  • 首先，您需要在 Outlook 日曆中選擇源會議。
  • 然後按快速訪問工具欄中的宏按鈕。
  • 立即，此會議將重新發送給尚未回复的與會者。

解決各種 Outlook 問題

當您使用 Outlook 時，可能會意外發生各種問題，例如突然“無響應”、彈出錯誤消息、崩潰等。 通常，您必須使用內部修復實用程序修復小問題。 但是，如果問題太嚴重而無法通過 Scanpst.exe 解決，則您別無選擇，只能藉助更強大、更可靠的修復工具，例如 DataNumen Outlook Repair。 精通 PST維修，從而超越其競爭對手。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 損壞的SQL 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM

立即分享：

評論被關閉。