如何快速將多封 Outlook 電子郵件中的所有超鏈接導出到 Excel

當您需要提取一封或多封電子郵件中的所有超連結時，逐一複製顯然很麻煩。本文將教您一種快速將多封電子郵件中的所有超連結匯出到 Excel 的方法。

由於某些原因，例如在所有發送的電子郵件中記錄超鏈接，您需要提取超鏈接。 毫無疑問，手動提取和復制它們是不可取的。 您一定渴望一種更智能的方法，例如使用 VBA。 這裡我們將向您分享這樣一段VBA代碼，只需單擊一下即可將許多電子郵件中的所有超鏈接導出到Excel。

將多封電子郵件中的所有超鏈接導出到 Excel

1. 首先，像往常一樣啟動 Outlook 程式。
2. 然後，在 Outlook 窗口中，您需要點擊“Alt + F11”鍵按鈕。
3. 您將立即可以訪問 Outlook VBA 編輯器。
4. 接下來，您需要啟用「Microsoft Word 物件庫」和「Microsoft Excel 物件庫」。點擊“工具”>“引用”，然後在彈出的對話框中啟用它們。
5. 接下來，您需要打開一個未使用的模塊，其中您必須將下面的VBA代碼複製到該模塊中。

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. 之後，您可以退出當前的VBA編輯器窗口。
7. 稍後訪問“Outlook 選項”自定義快速訪問工具欄，將新添加的宏添加到快速訪問工具欄。
8. 最後，您可以嘗試一下：

• 首先，在電子郵件列表中，選擇您要提取其超鏈接的電子郵件。
• 然後，在快速訪問工具欄中單擊宏按鈕。
• 宏完成後，您將得到一個 Excel 文件，如下圖所示：

修復意外的 Outlook 問題

Outlook 問題有時會在沒有任何預兆的情況下發生。但是，對於一些小錯誤，Outlook 可以透過簡單的重新啟動或其…來恢復。 收件箱維修工具。 但如果遇到一些嚴重的麻煩，內功就起不到作用了。 此時，您的最後手段絕對是一個更有信譽和強大的工具，例如 DataNumen Outlook Repair.

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 損壞的mdf 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM