如何快速附加特定的幻燈片 PowerPoint 演示到您的Outlook電子郵件

如果要提取特定幻燈片 PowerPoint 演示文稿添加到單獨的新演示文稿，並將其附加到Outlook電子郵件中，則可以利用本文中共享的方式。

而不是附加整個 PowerPoint 演示文稿添加到電子郵件中，如果要附加演示文稿的特定幻燈片，通常需要先將特定幻燈片複製到新的演示文稿中。 太麻煩了。 因此，這裡我們將向您展示一種可以一次性實現的方法。

附加一個的特定幻燈片 PowerPoint 演示到電子郵件

1. 首先，打開特定 PowerPoint 介紹。
2. 那麼，在 PowerPoint 在應用程序窗口中，按“ Alt + F11”鍵訪問VBA編輯器。
3. 接下來，在新窗口中，通過單擊“插入”>“模塊”來創建一個新模塊。
4. 隨後，將以下VBA代碼複製並粘貼到該模塊中。

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. 之後，您可以關閉當前窗口。
6. 稍後，轉到“文件”>“選項”>“快速訪問工具欄”，將新的宏添加到快速訪問工具欄。
7. 最後，您可以嘗試使用此宏。

• 首先，選擇要擷取的特定幻燈片。
• 然後，單擊快速訪問工具欄中的宏按鈕。
• 一次，將顯示Outlook電子郵件，其中有一個 PowerPoint 從源演示文稿中提取的演示文稿。

使用有效的恢復工具

眾所周知，Outlook具有內置的修復實用程序– 掃描儀。 但是，它可以輕鬆應對Outlook中的小故障。 如果您面臨的是嚴重損壞，則不會產生任何效果。 那時，您別無選擇，只能選擇另一個功能強大且值得信賴的修復工具，例如 DataNumen Outlook Repair。 有了它，您將能夠挽救損壞的Outlook文件。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 損壞的mdf 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM