如何使用 VBA 將所有 Outlook 文件夾中的所有電子郵件批量標記為已讀

Outlook解決方案 2025 年 9 月 29 日
立即分享：

多個用戶渴望有一個解決方案來批量將所有電子郵件標記為已讀 在所有 Outlook 文件夾中。 在這篇文章中，我們將向您介紹這樣一種方法。  

眾所周知，將文件夾中的所有郵件標記為已讀很容易。 只需選擇並右鍵單擊該文件夾，然後在上下文菜單中選擇“全部標記為已讀”選項。 但如果有多個文件夾有未讀郵件，通過上述方式，就必須對文件夾一一進行操作。 太麻煩了。 因此，在這裡我們將向您分享一種更有效的方法，這將使您能夠批量實現它。

將所有 Outlook 文件夾中的所有電子郵件批量標記為已讀

  1. 首先，啟動 Outlook 應用程式。
  2. 然後，按“Alt + F11”訪問 Outlook VBA 編輯器。
  3. 接下來，在“Microsoft Visual Basic for Applications”窗口中，將以下代碼複製到未使用的模塊中。
Sub MarkAllItemsAsRead()
    Dim objStores As Outlook.Stores
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process all Outlook files
    Set objStores = Outlook.Application.Session.Stores
  
    For Each objStore In objStores
        Set objOutlookFile = objStore.GetRootFolder
 
        For Each objFolder In objOutlookFile.Folders
            'Process mail folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objUnreadItems As Outlook.Items
    Dim i As Integer
    Dim objItem As Object
    Dim objSubFolder As Outlook.Folder
 
    Set objUnreadItems = objCurFolder.Items.Restrict("[Unread]=True")
 
    'Mark all unread emails as read
    For i = 1 To objUnreadItems.Count
        Set objItem = objUnreadItems.Item(i)
        objItem.UnRead = False
        objItem.Save
    Next
 
    'Process subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubFolder In objCurFolder.Folders
           Call ProcessFolders(objSubFolder)
       Next
    End If
End Sub

VBA 代碼 - 將所有 Outlook 文件夾中的所有電子郵件批量標記為已讀

  1. 然後將光標置於第一個子程序中。
  2. 隨後，按“F5”鍵按鈕或單擊工具欄中的“運行”圖標。
  3. 最終，宏完成後，您可以返回郵件文件夾列表。
  4. 在那裡，您會看到所有未讀電子郵件都已標記為已讀，如屏幕截圖所示。所有電子郵件均已閱讀

擺脫 Outlook 數據丟失的痛苦

用戶可能已經接受了 Word 文檔和 Excel 工作簿很容易損壞的事實。 事實上，與這些文件類似，Outlook數據文件也容易受到損壞。 因此，如果您不願意經歷這種情況，您應該採取一些行動。 它應該包括預防措施，例如定期備份和阻止所有惡意軟件或病毒，以及一些緩解措施，例如了解如何啟動收件箱修復工具， 掃描儀 並保留強大的外部修復工具，例如 DataNumen Outlook Repair.

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 維修MDF 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM

立即分享：

評論被關閉。