如何在特定天數後自動刪除特定發件人的 Outlook 電子郵件

要讓您的 Outlook 自動刪除特定日期內特定發件人的電子郵件，您可以閱讀本文。 這裡我們將向您展示使用VBA代碼獲取它的詳細步驟。

說到自動刪除電子郵件，您可能首先想到“自動存檔”功能。 但是，它無法在自動歸檔電子郵件時過濾特定發件人。 因此，例如，如果您想在x天后自動刪除特定發件人的電子郵件，您應該使用其他方法，例如以下方法。

X 天后自動刪除特定發件人的電子郵件

1. 從一開始tar您的Outlook應用程序。
2. 然後，根據“如何在Outlook中運行VBA代碼“。
3. 接下來，將以下VBA代碼複製到“ ThisOutlookSession”項目中。

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. 之後，restart Outlook激活此宏。
5. 從那時起，每當來自特定發件人的新電子郵件到達收件箱時，都會為其分配一個特定的到期時間 - 收到後的特定天數。
6. 然後，每次你tart Outlook，Outlook 會自動檢查並刪除特定發件人的過期郵件。

損壞後恢復 Outlook 數據

也許您在 Outlook 中遇到過各種錯誤和麻煩。 那麼，您是否遇到過 Outlook 損壞的情況？ 例如，如果您經常不正確地退出 Outlook，您的 PST 文件往往會被損壞。 通常，在這種情況下，您可以選擇從備份中檢索 Outlook 數據。 或者你可以使用 收件箱維修工具 或可靠的外部工具，例如 DataNumen Outlook Repair.

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 恢復SQL 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM