如何在Outlook中標記電子郵件時自動創建新的約會

Outlook解決方案 2025 年 9 月 29 日

有些人希望在標記電子郵件時自動或快速創建新的Outlook約會。本文將介紹一種使用Outlook VBA實現它的方法。

有時，我可能會收到一封電子郵件，其中提到約會或會議。但這只是一封電子郵件，而不是Outlook中的常見會議項目。在這種情況下，我必須在Outlook日曆中手動創建一個新約會。那有點麻煩。因此，我希望Outlook可以自動創建一個新約會。但是，Outlook不支持我們在標記電子郵件時自動創建新約會的本機支持。因此，為了實現它，我選擇使用Outlook VBA。以下是詳細的VBA代碼和步驟。

標記電子郵件時自動創建新的約會

首先，切換到“開發人員”選項卡，然後單擊“代碼”組中的“ Visual Basic”按鈕。
然後在新的“ Microsoft Visual Basic for Applications”窗口中，需要雙擊“ ThisOutlookSession”以打開該項目。
接下來，將以下VBA代碼複製並粘貼到其中。

Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim oAppt As AppointmentItem
    Dim strMsg As String
    Dim nRes As Integer
 
    On Error Resume Next
 
    If TypeName(Item) = "MailItem" And Item.IsMarkedAsTask = True Then
       strMsg = "Do you want to create a new appointment"
       nRes = MsgBox(strMsg, vbYesNo + vbQuestion, "Confirm Creating Appointment")
       If nRes = vbYes Then
          Set oAppt = Application.CreateItem(olAppointmentItem)
          With oAppt
               .Subject = "New Appt: " & Item.Subject
               .Location = InputBox("Enter the Location, please.")
               'Type the concrete time, such as "12/29/2015 15:30"
               .Start = InputBox("Enter a specific time (format: MM/DD/YYYY hh:mm), please.")
               .Duration = 120
               .Body = "New Appointment: " & vbCrLf & vbCrLf & Item.Body
               .Attachments.Add Item
               .ReminderSet = True
               .ReminderMinutesBeforeStart = 30
               'Use ".Save" to directly save the new appointment
               .Display
          End With
       End If
 
      'To clear the flag on the email
      'If you want to keep email flagged, remove the following 4 lines
       With Item
            .ClearTaskFlag
            .Save
       End With
    End If
End Sub

隨後，您應該使用“用於VBA項目的數字證書”創建新證書並簽署當前的“ ThisOutlookSession”項目。
之後，您可以退出“ Visual Basic”窗口，並將宏設置更改為僅允許數字簽名的宏。
最終，您可以嘗試一下。

首先，投放電子郵件，然後單擊“標記”圖標。您將得到提示，如以下屏幕截圖所示：
選擇“是”後，將要求您指定位置並點擊“確定”按鈕。
然後，您需要指定約會時間。
最後，單擊“確定”後，將打開一個新約會，如下圖所示：

注意：

在此VBA代碼中，提醒默認設置為30分鐘。您可以隨意在代碼中進行更改。
該代碼將約會持續時間設置為120分鐘，即2小時。您可以根據需要更改“ .Duration = 120”行。
如果您未指定具體時間，則默認情況下，新約會將設置為當前日期和時間。
您可以添加“ .Save”行直接保存約會。

解決Outlook問題

眾所周知，Outlook可能會遇到各種問題。最壞的情況一定是Outlook損壞。如果您的Outlook文件已損壞，並且已經準備好備份，則可以輕鬆還原您的損壞的Outlook數據從備份。但是，如果沒有備份，則需要修復損壞的Outlook文件。在這種情況下，您可以使用內置的修復工具Scapst.exe，也可以使用經驗更豐富的工具，例如 DataNumen Outlook Repair.

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括修復 SQL Server mdf數據庫問題和Outlook修復軟件產品。欲了解更多信息，請訪問萬維網。datanumen.COM