在不同頁面中打印不同類別的 Outlook 任務列表的 2 種方法

如果您已經為 Outlook 任務分配了各種顏色類別，現在想要在不同頁面中打印不同類別的任務列表，您可以參考本文。 下面小編就給大家分享2種獲取方法。

為了對您的任務進行分類和管理，您可能已將顏色類別應用於您的任務。 現在，如果您想在不同頁面中打印不同類別的任務列表，請繼續閱讀。 下面我們將為您介紹2種獲取方式。

方法一：手動一一打印任務列表

1. 首先，在 Outlook 中，訪問“任務”窗格。
2. 然後，打開一個任務文件夾。
3. 接下來，按“Ctrl + E”激活“搜索”功能區。
4. 之後，在“搜索”選項卡上，單擊“分類”按鈕。
5. 從下拉列表中選擇顏色類別。
6. 然後，列表中將僅保留所選類別的任務。
7. 現在，轉到“文件”>“打印”打印此任務列表。
8. 隨後，以同樣的方式，手動將其他顏色類別的任務列表一一打印出來。

方法二：通過VBA批量打印任務列表

1. 首先，按照“觸發 VBA 編輯器”如何在Outlook中運行VBA代碼“。
2. 然後，添加對“MS Excel Object Lib”的引用rary”，按照“如何添加對像庫rary VBA中的參考“。
3. 接下來，將以下VBA代碼複製到模塊中。

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. 然後，按“F5”鍵立即運行該宏。
5. 宏完成後，不同類別的任務列表將打印在不同的頁面中，如下圖所示。

從受損的 PST 文件中取回有價值的數據

如果您遇到無法訪問 PST 文件的問題，下一步無疑是 PST維修。 這種情況，您可以先嘗試收件箱修復工具。 如果失敗，您可以繼續嘗試其他外部工具，例如 DataNumen Outlook Repair。 它能夠快速恢復 PST 數據。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 恢復mdf 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM