Cách nhanh chóng lấy danh sách tất cả các tệp Outlook PST trên ổ đĩa cục bộ của bạn thông qua VBA

giải pháp triển vọng Tháng Chín 29, 2025

Nếu bạn hy vọng có được danh sách tất cả các tệp Outlook PST được lưu trữ trên ổ đĩa cục bộ của PC, bạn có thể sử dụng đoạn mã VBA được hiển thị trong bài viết này. Nó có thể cho phép bạn có được nó trong thời gian nhanh chóng.

Có thể bạn đã tạo và lưu trữ nhiều tệp Outlook PST trên một phân vùng của máy tính. Tuy nhiên, theo thời gian, bạn có thể quên vị trí cụ thể của các tệp PST này. Trong trường hợp này, bạn có thể muốn nhanh chóng tìm ra chúng và đạt được danh sách thông tin của chúng, bao gồm tên, kích thước và đường dẫn. Để đáp ứng yêu cầu này, sau đây chúng tôi sẽ giới thiệu một cách hiệu quả.

Nhận danh sách tất cả các tệp Outlook PST trên ổ đĩa cục bộ của bạn

Trước tiên, hãy mở chương trình Outlook của bạn.
Sau đó, truy cập trình soạn thảo Outlook VBA của bạn có tham khảo bài viết trước của tôi – “Cách chạy mã VBA trong Outlook của bạn".
Tiếp theo, sao chép và dán mã VBA sau vào “ThisOutlookSession” hoặc một mô-đun không sử dụng.

Sub FindAllOutlookPSTFiles()
    Dim objWMIService As Object
    Dim objPSTFiles As Object
    Dim objPSTFile As Object
    Dim i As Long
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim strTextFile As String
    Dim objTextFile As Object
 
    'Find All PST Files on Drive C
    'You can change "C:" to the other drive letter as per your needs
    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
    Set objPSTFiles = objWMIService.ExecQuery ("Select * from CIM_DataFile Where Extension = 'pst' AND Drive = 'C:'")
 
    If objPSTFiles.count > 0 Then
 
       'Create a text file
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTextFile = "E:\PST_Files_on_Drive_C.txt"
       Set objTextFile = objFileSystem.CreateTextFile(strTextFile, True)
 
       i = 1
 
       For Each objPSTFile In objPSTFiles
           'Input the PST file name, size and path into the text file
           objTextFile.Write (i & ". " & objPSTFile.filename & "." & objPSTFile.Extension & vbCrLf & " Size: " & objPSTFile.FileSize / 1024 & "KB" & vbCrLf & " Path: " & objPSTFile.Drive & objPSTFile.Path & vbCrLf & vbCrLf)
           i = i + 1
       Next
 
       objTextFile.Close
 
       'Open this text file
       Shell "C:\Windows\Notepad.exe " & strTextFile, 1
    Else
       MsgBox "There isn't PST file on this drive!", vbExclamation + vbOKOnly
    End If
End Sub

Sau đó, bạn có thể thử macro này ngay bây giờ. Chỉ cần nhấn nút phím “F5”.
Khi macro hoàn tất, bạn sẽ thấy một tệp văn bản hiển thị, trông giống như ảnh chụp màn hình sau:

Sử dụng Công cụ sửa chữa trong trường hợp Outlook gặp sự cố

Các loại lỗi có thể xảy ra với Outlook của bạn theo thời gian. Nếu bạn không giải quyết chúng kịp thời, cuối cùng thì một ngày nào đó bạn sẽ gặp phải sự cố Outlook nghiêm trọng. Do đó, bạn nên giữ một tiện ích sửa chữa PST mạnh mẽ và có kinh nghiệm ở gần, chẳng hạn như DataNumen Outlook Repair. Nó được thiết kế đặc biệt để sửa chữa PST tài liệu. Do đó, nó có khả năng cứu bạn khỏi mất dữ liệu PST.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm tham nhũng sql và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm