Cách tìm nhanh các đoạn một câu trong tài liệu Word của bạn

Trong bài viết này, chúng tôi muốn giới thiệu cho bạn cách nhanh chóng tìm tất cả các đoạn văn chỉ có một câu trong tài liệu Word của bạn bằng VBA.

Đôi khi, một số tài liệu có thể có những yêu cầu rất cụ thể về định dạng và cấu trúc của chúng. Ví dụ: bạn không được phép viết đoạn văn chỉ có một câu. Những đoạn văn này không khó nhận biết nhưng cần có thời gian, đặc biệt là một tài liệu dài.

Hôm nay, chúng tôi sẽ cung cấp cho bạn cách nhanh chóng để chỉ định tất cả các đoạn một câu trong tài liệu của bạn.

Tìm tất cả các đoạn một câu trong một tài liệu

1. Đầu tiên, Word tính một khoảng thời gian là một câu. Vì vậy, nếu có những từ như “Mr.” hoặc “Ms.”, Word coi đó là một câu. Để loại trừ sự xao lãng như vậy, bạn cần thay thế “Mr.” với “Ông”. Và khi tìm xong đoạn của câu đơn, bạn có thể thay đổi chúng trở lại. Để thay thế từ, bạn có thể tham khảo link này: Cách tìm và thay thế nhiều mục trong tài liệu Word của bạn
2. Thứ hai, nhấn “Alt + F11” để kích hoạt trình soạn thảo VBA.
3. Sau đó nhấp vào dự án "Bình thường".
4. Nhấp vào tab “Chèn” trên thanh menu và chọn “Mô-đun” trên menu thả xuống của nó.
5. Tiếp theo nhấp đúp chuột vào mô-đun để mở nó.
6. Dán các mã sau vào mô-đun:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Cuối cùng nhưng không kém phần quan trọng, nhấp vào nút “Run” hoặc nhấn “F5”.

Bạn sẽ nhận được một hộp thông báo như vậy, cho bạn biết công việc đã hoàn tất.

Tìm tất cả các đoạn một câu trong nhiều tài liệu

1. Trước tiên, bạn cần đặt tất cả các tài liệu cần nhắm mục tiêu vào một thư mục.
2. Sau đó cài đặt và chạy macro dưới đây:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Trong cửa sổ “Duyệt” mở ra, chọn thư mục nơi bạn lưu giữ tài liệu và nhấp vào “OK”.

Sau đó, macro sẽ đánh dấu tất cả các đoạn văn có một câu và để tài liệu mở. Nếu tài liệu không chứa đoạn một câu, nó sẽ bị đóng. Ngoài ra còn có hộp thông báo, cho biết số đoạn văn trong mỗi tài liệu.

Xử lý sự cố mất dữ liệu

Lỗi người dùng và mất điện đột ngột có thể dẫn đến việc Word bị chết. Trong khi một Word bị thu gọn không chỉ có thể ảnh hưởng đến công việc hàng ngày mà còn dẫn đến tài liệu thiệt hạiĐây chắc chắn không phải là phần khó chịu nhất của một thảm họa dữ liệu. Tốt hơn hết là nên sử dụng một công cụ sửa chữa để khôi phục dữ liệu ngay lập tức.

Giới thiệu tác giả:

Vera Chen là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm phục hồi excel và pdf sửa chữa các sản phẩm phần mềm. Để biết thêm thông tin, hãy truy cập www.datanumennăm