Cách xuất nhanh tổng thời gian dành cho các cuộc hẹn Outlook trong từng danh mục màu

giải pháp triển vọng Tháng Chín 29, 2025

Nếu muốn tạo báo cáo về tổng thời gian bạn dành cho các cuộc hẹn theo từng danh mục màu, bạn có thể sử dụng phương pháp được giới thiệu trong bài viết này. Nó có thể giúp bạn thực hiện việc này trong thời gian nhanh chóng mà không cần phải đếm thủ công.

Nhiều người dùng đã quen với việc ghi lại hầu hết các hoạt động của họ trong lịch Outlook. Ngoài ra, để quản lý và phân loại chúng dễ dàng hơn, họ gán các danh mục cho từng hoạt động. Trong trường hợp này, một số người dùng muốn tạo báo cáo hiển thị tổng thời gian dành cho các mục trong lịch thuộc mỗi danh mục màu sắc. Chắc chắn, việc đếm và nhập thủ công rất rắc rối. Do đó, ở đây chúng tôi sẽ chia sẻ một cách có thể thực hiện nhiệm vụ này chỉ bằng một cú nhấp chuột đơn giản.

Xuất Tổng thời gian dành cho các cuộc hẹn trong từng danh mục màu

Trước tiên, hãy khởi chạy ứng dụng Outlook của bạn.
Sau đó, sau khi vào cửa sổ Outlook, bạn có thể nhấn vào nút phím “Alt + F11”.
Sau đó, bạn sẽ có quyền truy cập vào cửa sổ “Microsoft Visual Basic for Application”.
Tiếp theo, bạn cần kích hoạt “Thư viện đối tượng Microsoft Excel”. Bạn có thể nhấp vào “Công cụ” > “Tham chiếu” để thực hiện việc này.
Sau đó, bạn nên tìm và mở một mô-đun không được sử dụng.
Sau đó, bạn cần sao chép mã VBA sau vào mô-đun này.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

Cuối cùng, bạn có thể kích hoạt macro này bằng cách nhấp vào biểu tượng “Chạy” trên thanh công cụ hoặc nhấn nút phím “F5”.
Sau đó, bạn sẽ được yêu cầu chọn một lịch cụ thể.
Sau khi bạn chọn và nhấn “OK”, macro sẽ tiếp tục chạy. Sau khi hoàn tất, sẽ có một tệp Excel mới hiển thị ở chế độ nền.
Bạn có thể truy cập nó. Nó sẽ trông giống như ảnh chụp màn hình sau:

Để mắt đến các mối đe dọa tiềm ẩn xung quanh Outlook của bạn

Người dùng Outlook nên đề phòng tất cả các rủi ro tiềm ẩn, bao gồm các tệp đính kèm email không xác định, các liên kết được nhúng và lỗi của con người. Nếu không, Outlook của bạn có thể bị hỏng bất cứ lúc nào. Ngoài ra, việc sao lưu dữ liệu Outlook thường xuyên và duy trì một công cụ sửa chữa chuyên dụng là những vấn đề cần thiết. DataNumen Outlook Repair là một trong những công cụ sửa chữa được đánh giá cao nhất. Nó có thể sửa chữa triển vọng vấn đề trong nháy mắt.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm mdf bị hư hỏng và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm