Cách xuất nhanh tất cả tệp đính kèm hình ảnh của email Outlook sang trang tính Excel

giải pháp triển vọng Tháng Chín 29, 2025

Nếu bạn muốn xuất nhanh tất cả các tệp đính kèm hình ảnh của email Outlook sang bảng tính Excel, bạn có thể tham khảo bài viết này. Ở đây chúng tôi sẽ chỉ cho bạn một cách hiệu quả hơn là xuất thủ công.

Khi nhận được email có chứa nhiều tệp đính kèm hình ảnh, nếu bạn muốn sử dụng chúng để lập báo cáo trong Excel, chắc hẳn bạn sẽ muốn tìm cách xuất hàng loạt các hình ảnh này vào một bảng tính Excel. Sau đây, chúng tôi sẽ giới thiệu cho bạn phương pháp đó.

Xuất tất cả tệp đính kèm hình ảnh của email sang bảng tính Excel

Để bắt đầu, hãy truy cập ứng dụng Outlook của bạn theo cách thông thường.
Sau đó, trong cửa sổ Outlook, nhấn phím tắt “Alt + F11”, thao tác này sẽ hiển thị cửa sổ “Microsoft Visual Basic for Applications”.
Trong màn hình này, bạn cần mở một mô-đun không được sử dụng hoặc chèn thẳng một mô-đun mới.
Tiếp theo, bạn phải sao chép đoạn mã VBA bên dưới vào mô-đun này.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

Sau đó, bạn có thể thoát macro.
Sau đó, đi tới “Tệp” > “Tùy chọn” > “Thanh công cụ truy cập nhanh” để thêm macro này vào Thanh công cụ truy cập nhanh.
Cuối cùng, bạn có thể thử macro này ngay bây giờ.

Đầu tiên, chọn hoặc mở một email nguồn.
Sau đó, bấm vào nút macro trong Thanh công cụ truy cập nhanh.
Khi macro hoàn thành, bạn sẽ nhận được một trang tính Excel, được hiển thị như ảnh chụp màn hình sau:

Bảo vệ tệp Outlook khỏi bị hỏng

Được biết, Outlook dễ bị hỏng. Do đó, chúng ta nên hiểu cách bảo vệ biểu mẫu Outlook khỏi tham nhũng. Trước hết, để ngăn chặn các cuộc tấn công của vi-rút, cần phải cài đặt phần mềm chống vi-rút và không bao giờ tải xuống tệp đính kèm không xác định. Bên cạnh đó, tốt hơn hết là chúng ta nên nắm giữ một công cụ sửa chữa hiệu quả, chẳng hạn như DataNumen Outlook RepairNó có thể cung cấp biện pháp khắc phục hiệu quả nhất trong trường hợp này. Tham nhũng.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm phục hồi sql và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm