Cách tạo nhanh nhóm liên hệ từ tất cả liên hệ Outlook với chức danh công việc cụ thể

Để liên lạc với những người liên hệ có chức danh công việc cụ thể dễ dàng hơn, bạn có thể muốn nhanh chóng tạo một nhóm liên hệ từ những người liên hệ này. Bây giờ, trong bài viết này, chúng tôi sẽ chia sẻ với bạn một phương pháp nhanh chóng.

Nếu bạn thường xuyên gửi hàng loạt email, nhiệm vụ hoặc lời mời họp đến những người liên hệ có chức danh công việc cụ thể, sẽ thuận tiện hơn nhiều nếu bạn tạo một nhóm liên hệ từ họ. Nói chung, theo cách tiêu chuẩn, trước tiên bạn cần tạo một nhóm liên hệ mới, sau đó thêm từng liên hệ vào nhóm với tư cách thành viên. Đó là một chút rắc rối. Vì vậy, trong phần tiếp theo, chúng tôi sẽ hướng dẫn bạn cách lấy nó nhanh hơn nhiều.

Tạo Nhóm liên hệ từ tất cả các liên hệ có chức danh cụ thể

1. Đầu tiên, trong thư mục Danh bạ, hãy chọn một liên hệ có chức danh công việc cụ thể.
2. Sau đó, nhấn “Alt + F11” để truy cập trình soạn thảo Outlook VBA.
3. Tiếp theo, sao chép mã VBA sau vào một mô-đun hoặc dự án trống.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Sau đó, di chuyển con trỏ vào chương trình con đầu tiên.
5. Cuối cùng, nhấn vào nút phím “F5” để chạy macro này.
6. Khi macro hoàn tất, một nhóm liên hệ mới sẽ hiển thị. Nó chứa tất cả những người liên hệ có cùng chức danh công việc với người liên hệ đã chọn ở Bước 1.

Bảo vệ dữ liệu Outlook hiệu quả

Mặc dù Outlook có nhiều tính năng nhưng nó không thể thoát khỏi thực tế là nó dễ bị tấn công. Vì vậy, nếu không muốn mất đi dữ liệu Outlook quý giá của mình, bạn phải nỗ lực để bảo vệ nó. Chẳng hạn, bạn cần tạo bản sao lưu định kỳ cho dữ liệu Outlook. Ngoài ra, nếu có khả năng chi trả, bạn nên trang bị một công cụ sửa chữa PST tiên tiến, chẳng hạn như DataNumen Outlook Repair, có thể sửa chữa PST dữ liệu trong nháy mắt.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm sql bị hỏng và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm