Cách xác thực hàng loạt tất cả các siêu liên kết trong tài liệu Word của bạn thông qua VBA

Lời giải Tháng Chín 28, 2025

Trong bài viết này, chúng tôi sẽ chỉ cho bạn một cách tự động để nhanh chóng xác thực hàng loạt tất cả các siêu liên kết trong tài liệu Word của bạn thông qua VBA.

Một tài liệu Word có thể chứa nhiều siêu liên kết, thậm chí hàng trăm liên kết. Trong số đó, một số liên kết không hợp lệ không dẫn bạn đến đúng trang web. Vì vậy, chúng tôi muốn cung cấp cho bạn cách kiểm tra nhanh tất cả các liên kết trong tài liệu thông qua VBA.

Cài đặt và lưu Macro từ

Trước hết, hãy mở trình soạn thảo VBA bằng “Alt+ F11”.
Sau đó nhấp vào dự án "Bình thường".
Tiếp theo, nhấp vào tab "Chèn" trên menu thanh công cụ.
Và chọn “Mô-đun” trên menu.
Nhấp đúp chuột vào mô-đun để mở không gian chỉnh sửa và dán các mã sau vào đó:

Function CheckURL(strURL As String) As Boolean
  Dim objDemand As Object
  Dim varResult As Variant
 
  On Error GoTo ErrorHandler
  Set objDemand = CreateObject("WinHttp.WinHttpRequest.5.1")
 
  With objDemand
    .Open "GET", strURL, False
    .Send
    varResult = .StatusText
  End With
 
  Set objDemand = Nothing
 
  If varResult = "OK" Then
    CheckURL = True
  Else
    CheckURL = False
  End If
 
ErrorHandler:
End Function

Sub ReturnURLCheck()
  Dim objLink As Hyperlink
  Dim strLinkText As String
  Dim strLinkAddress As String
  Dim strResult As String
  Dim nInvalidLink As Integer, nTotalLinks As Integer
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
 
  Set objDoc = ActiveDocument
  nTotalLinks = objDoc.Hyperlinks.Count
  nInvalidLink = 0
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkText = objLink.Range.Text
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        nInvalidLink = nInvalidLink + 1
        strResult = frmCheckURLs.txtShowResult.Text
        frmCheckURLs.txtShowResult.Text = strResult & nInvalidLink & ". Invalid Link Information:" & vbNewLine & _
                                          "Displayed Text: " & strLinkText & vbNewLine & _
                                           "Address: " & strLinkAddress & vbNewLine & vbNewLine
      End If
    Next objLink
 
    frmCheckURLs.txtTotalLinks.Text = nTotalLinks 
    frmCheckURLs.txtNumberOfInvalidLinks.Text = nInvalidLink
    frmCheckURLs.Show Modal
 
  End With
  Application.ScreenUpdating = True
End Sub

Sub HighlightInvalidLinks()
  Dim objLink As Hyperlink
  Dim strLinkAddress As String
  Dim strResult As String
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        objLink.Range.HighlightColorIndex = wdYellow
      End If
    Next objLink
  End With
End Sub

Tiếp theo nhấp vào “Lưu”.
Sau đó gán một nút cho macro. Bạn có thể tham khảo bài viết sau để biết thông tin chi tiết:

Cách xóa định dạng của văn bản đã dán bằng Macro và VBA trong Word của bạn

Tạo biểu mẫu người dùng

Với biểu mẫu người dùng, bạn có thể thấy rõ tổng số liên kết trong tài liệu hiện tại, số lượng liên kết không hợp lệ và nhiều thông tin chi tiết khác.

Đầu tiên, nhấp vào “Chèn” trên thanh công cụ một lần nữa. Nhưng lần này, hãy chọn “UserForm”.
Tiếp theo, nhấn “F4” để mở “Cửa sổ thuộc tính” ở góc dưới bên trái. Kích thước cửa sổ có thể điều chỉnh được.
Bây giờ hãy đặt tên cho biểu mẫu người dùng là “frmCheckURLs”.
Đặt chú thích là “Kiểm tra URL”.
Sau đó đặt phông chữ đúng cách.
Tiếp theo nhấp vào nút “Hộp công cụ” trên thanh công cụ.
Bây giờ hãy nhấp vào “Nhãn” trên hộp công cụ. Sử dụng chuột để kéo nhãn hình chữ nhật trên biểu mẫu người dùng.
Bấm vào nhãn để kích hoạt cửa sổ thuộc tính của nó. Đặt tên nhãn là “lblInvalidURLs” và chú thích nhãn là “URL không hợp lệ:”.
Tiếp theo, chọn phông chữ và màu nền phù hợp cho văn bản chú thích nhãn.
Chọn “Hộp văn bản” trên hộp công cụ và chèn hộp văn bản vào biểu mẫu người dùng. Điều chỉnh kích thước của nó.
Sau đó, đặt tên hộp văn bản là “txtShowResult”.
Đặt phông chữ và màu trước như mong muốn.
Tìm “MultiLine” và đặt nó là “True”.
Tìm “Thanh cuộn” và chọn một thanh dọc.
Tiếp theo, tạo thêm hai nhãn và hộp văn bản.
Sau đó, đặt tên cho nhãn đầu tiên là “lblTotalLinks” và đặt chú thích là “Tổng số liên kết trong tài liệu này”.
Và đặt tên cho nhãn thứ hai là “lblNumberOfInvalidLinks” và đặt chú thích là “Số lượng liên kết không hợp lệ”.
Đặt tên cho hộp văn bản đầu tiên là “txtTotalLinks” và hộp thứ hai là “txtNumberOfInvalidLinks”.
Sau đó tìm điều khiển nút lệnh trên hộp công cụ. Tạo hai nút lệnh, chẳng hạn như dưới đây:
Đặt tên cho nút đầu tiên là “cmdbtnClose” và văn bản chú thích của nó là “Close”.
Đặt tên cho nút thứ hai là “btnCloseAndHighlightInvalidURLs” và văn bản chú thích của nó là “Đóng & Đánh dấu các URL không hợp lệ”.
Tiếp theo nhấp đúp vào nút “Đóng” và nút “Close & Highlight Invalid URLs” tương ứng. Nhập mã như sau:

Chạy Macro

Nhấp vào nút bạn gán cho macro. Đây là hiệu ứng cuối cùng:

Bạn có thể xem thông tin chi tiết về từng liên kết bị lỗi trên hộp văn bản lớn bên trái. Và bạn có thể chọn đóng biểu mẫu người dùng trực tiếp hoặc đóng nó trong khi đánh dấu tất cả các liên kết bị hỏng trong tài liệu.

Xử lý các vấn đề từ một cách cẩn thận

Word rất dễ mắc lỗi. Vì vậy, nó trở nên cực kỳ quan trọng để sửa từ Đúng vậy. Hầu hết các trường hợp, công cụ tích hợp sẵn không thể giúp bạn nhiều. Do đó, lựa chọn tốt nhất của bạn là sử dụng công cụ sửa chữa của bên thứ ba.

Giới thiệu tác giả:

Vera Chen là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm sửa chữa xlsx và pdf sửa chữa các sản phẩm phần mềm. Để biết thêm thông tin, hãy truy cập www.datanumennăm