Cách tự động đặt thời gian nhắc nhở khác nhau cho các cuộc họp Outlook với các danh mục màu khác nhau

Nếu bạn đang phân loại cuộc họp Outlook theo danh mục màu và muốn đặt thời gian nhắc nhở khác nhau cho các cuộc họp theo danh mục màu khác nhau, bạn có thể tham khảo bài viết này. Ở đây chúng tôi sẽ hướng dẫn bạn cách nhận ra điều đó với Outlook VBA.

Ví dụ, bạn đang chia các cuộc họp thành hai nhóm. Một nhóm thuộc loại “Hẹn họp ngoài văn phòng” vì địa điểm họp quá xa, và nhóm còn lại thuộc loại “Hẹn họp tại văn phòng” vì địa điểm họp ngay tại đây. Bây giờ, bạn muốn Outlook tự động đặt thời gian nhắc nhở cho cuộc họp “ngoài văn phòng” là 1 giờ trước khi bắt đầu và cuộc họp “tại văn phòng” là 15 phút trước khi bắt đầu. Dựa trên yêu cầu này, chúng tôi sẽ chia sẻ một phương pháp nhanh chóng như sau.

Tự động đặt lời nhắc khác nhau cho các cuộc họp ở các danh mục màu khác nhau

1. Để bắt đầu, hãy khởi chạy ứng dụng Outlook của bạn.
2. Sau đó, nhấn nút phím “Alt + F11” để truy cập cửa sổ soạn thảo VBA.
3. Tiếp theo, trong cửa sổ tiếp theo, sao chép và dán mã VBA bên dưới vào dự án “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Sau đó, bạn cần nhấp vào chương trình con “Application_Startup” và nhấn phím “F5” để chạy macro này.
5. Kể từ đó, mỗi khi có cuộc họp mới được thêm vào lịch mặc định hoặc khi bạn thay đổi cuộc họp hiện có, Outlook sẽ tự động kiểm tra các danh mục của cuộc họp và tự động đặt thời gian nhắc nhở khác nhau.

Loại bỏ lỗi Outlook

Thỉnh thoảng, Outlook có thể gặp phải nhiều sự cố khác nhau. Do đó, việc người dùng học cách xử lý các vấn đề của Outlook là vô cùng quan trọng. Trước hết, bạn nên thường xuyên sao lưu dữ liệu Outlook. Hơn nữa, nếu có thể, bạn nên giữ một bản sao lưu mạnh mẽ. Sửa chữa Outlook công cụ gần đó, chẳng hạn như DataNumen Outlook Repair. Nó có thể quét tệp PST của bạn để tìm ra các vấn đề về Outlook và sau đó giải quyết chúng một cách dễ dàng.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm phục hồi sql và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm