3 cách nhanh chóng để xóa hàng và cột trống trong bảng Word của bạn

Trong bài viết này, chúng tôi sẽ hướng dẫn bạn 3 cách nhanh chóng để xóa các hàng và cột trống trong bảng Word của bạn.

Các bảng rất cần thiết cho một tài liệu, đặc biệt là trong việc chứa các loại dữ liệu khác nhau. Đôi khi, một bảng dài có thể vượt quá một trang và mở rộng ra nhiều trang. Vì vậy, khi một bảng trở nên dài và phức tạp, bạn có thể thực hiện các biện pháp để đơn giản hóa nó. Ví dụ: bạn có thể xóa các hàng và cột trống không cần thiết.

Sau đây là 3 phương pháp bạn có thể sử dụng.

Phương pháp 1: Xóa hàng và cột trống theo cách thủ công

1. Đầu tiên, chọn một hàng hoặc một cột trống.
2. Sau đó nhấp chuột phải để có menu ngữ cảnh. Trên menu, chọn “Xóa hàng” hoặc “Xóa cột” tương ứng.

Thật không may, bạn không thể chọn nhiều hàng hoặc cột không liên tiếp và xóa chúng cùng với cách này. Về nhu cầu này, bạn có thể tham khảo bài viết trước của chúng tôi: 5 phương pháp nhanh chóng để xóa hàng loạt nhiều hàng hoặc nhiều cột trong bảng Word của bạn

Phương pháp 2: Xóa hàng loạt tất cả các hàng và cột trống trong bảng

Phương pháp 1 có hạn chế của nó. Vì vậy, chúng tôi sẽ cung cấp cho bạn cách xóa hàng loạt hàng và cột trong bảng thông qua mã VBA.

1. Trước tiên, hãy đặt con trỏ vào bên trong bảng đích.
2. Thứ hai, kích hoạt trình chỉnh sửa VBA bằng cách nhấn “Alt + F11”.
3. Trong trình chỉnh sửa, trước tiên hãy nhấp vào dự án “Bình thường”.
4. Sau đó nhấp vào tab “Chèn” trên thanh menu.
5. Trên menu thả xuống, chọn “Mô-đun”.
6. Nhấp đúp chuột vào mô-đun để mở và dán mã sau vào đó:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Cuối cùng, nhấp vào nút “Run” trên thanh menu hoặc nhấn “F5”.

Trong vài giây, bạn sẽ xóa tất cả các hàng và cột trống trong bảng đó.

Phương pháp 3: Xóa hàng loạt tất cả các hàng và cột trống trong tất cả các bảng trong tài liệu

1. Trước hết, hãy lặp lại các bước trong phương pháp 2 để cài đặt và chạy macro.
2. Chỉ lần này, thay thế macro đó bằng cách sau:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Khôi phục tài liệu bị hỏng

Hiện nay có nhiều cách để khôi phục dữ liệu bị mất. Ví dụ, sao lưu dữ liệu luôn là ưu tiên hàng đầu. Nếu cách đó không đáp ứng được nhu cầu lấy lại thông tin mới nhất, bạn có thể thử các phương pháp khác. tài liệu sửa chữa công cụ.

Giới thiệu tác giả:

Vera Chen là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm xlsx sửa chữa và pdf sửa chữa các sản phẩm phần mềm. Để biết thêm thông tin, hãy truy cập www.datanumennăm