2 phương pháp để đếm nhanh email theo người gửi trong Outlook của bạn

giải pháp triển vọng Tháng Chín 29, 2025

Nếu bạn muốn đếm email theo người gửi, bạn có thể tham khảo bài viết này. Ở đây chúng tôi sẽ đưa ra 2 cách tiếp cận nhanh chóng cho bạn.

Để biết người gửi nào hoạt động tích cực nhất, bạn có thể muốn đếm số lượng email theo người gửi. Mặc dù Outlook không cung cấp tính năng trực tiếp cho việc này, bạn vẫn có thể tìm một số cách giải quyết thay thế, chẳng hạn như Phương pháp 1 dưới đây. Nếu bạn thấy Phương pháp 1 quá tốn thời gian, bạn có thể chọn Phương pháp 2. Phương pháp này hiệu quả hơn nhiều vì nó sử dụng VBA để nhanh chóng đếm số lượng email theo người gửi và xuất số liệu sang Excel. Bây giờ hãy đọc tiếp để tìm hiểu chi tiết hai cách này. Ở đây chúng ta sẽ lấy email trong Hộp thư đến làm ví dụ.

Phương pháp 1: Nhận số lượng sau khi nhóm các mục theo trường “Từ”

Để bắt đầu, hãy khởi chạy ứng dụng Outlook.
Sau đó, mở thư mục hộp thư đến.
Tiếp theo, chuyển sang tab “Xem”.
Sau đó, chọn “Từ” trong nhóm “Sắp xếp”.
Đồng thời, tất cả các mục trong hộp thư đến đã được tách thành các nhóm khác nhau theo những người gửi khác nhau.
Bây giờ, để đếm các mục từ một người gửi cụ thể, bạn có thể chọn tất cả các mục trong nhóm liên quan và nhấn phím “Enter”. Trong cảnh báo bật lên, bạn có thể xem số lượng.

Điều này có nghĩa là khá dễ dàng, nhưng số lượng mục thực sự bao gồm các loại mục khác, như lời mời họp, yêu cầu nhiệm vụ và biên lai, không chỉ số lượng email. Như vậy, nếu chỉ muốn đếm số email, bạn có thể sử dụng cách sau để thay thế.

Phương pháp 2: Đếm email theo người gửi với Outlook VBA

Trước tiên, hãy nhấn tổ hợp phím “Alt + F11” trong Outlook.
Tiếp theo, hãy bật “Thư viện đối tượng MS Excel” theo hướng dẫn trong “Cách thêm tham chiếu thư viện đối tượng trong VBA".
Tiếp theo, sao chép mã bên dưới vào một mô-đun không sử dụng.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

Sau đó, nhấn nút phím “F5”.
Khi macro kết thúc, một tệp Excel mới sẽ được hiển thị.
Như bạn có thể thấy, nó chứa số lượng email trong hộp thư đến từ những người gửi khác nhau.

Xử lý các sự cố khó chịu về Outlook

Có thể bạn đã từng gặp phải nhiều sự cố trong Outlook của mình. Để giải quyết chúng một cách hiệu quả, bạn có thể mong đợi một cách linh hoạt và mạnh mẽ. Tuy nhiên, trên thực tế, không có một phương pháp như vậy. Điều bạn có thể làm là cẩn thận với các hoạt động của chính mình trong Outlook và tạo bản sao lưu thường xuyên. Tất nhiên, nếu có thể, chúng tôi khuyên bạn nên giữ sẵn một công cụ sửa lỗi có kinh nghiệm, chẳng hạn như DataNumen Outlook Repair. Nó có thể khắc phục các sự cố PST khác nhau và sửa chữa PST hỏng tập tin như một làn gió.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm lấy lại Sql Server và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm