Paano Mabilis na Mag-export ng isang Outlook Folder sa Lahat ng Mga Subfolder at Item sa isang Windows Folder

Sa mga oras, baka gusto mong i-batch ang pag-export ng isang folder ng Outlook kasama ang lahat ng mga subfolder at item sa isang folder ng Windows. Ituturo sa iyo ng artikulong ito tulad ng isang pamamaraan na inilalapat ang Outlook VBA.

Kapag nais mong i-export ang isang folder ng Outlook sa lokal na drive kasama ang lahat ng mga item sa parehong istraktura ng folder, kung pipiliin mong i-save at i-export nang manu-mano, aabutin ka ng maraming oras. Kaya, bakit hindi ka gumamit ng ibang mga paraan, tulad ng anumang mga tool sa pag-export o mga code ng VBA? Dito ay ilalantad namin sa iyo ang isang piraso ng VBA code. Papayagan ka nitong makamit ito tulad ng isang simoy.

I-export ang Lahat ng Mga Subfolder at Item sa isang Outlook Folder sa isang Windows Folder

1. Sa pinakasimula pa lang, simulan ang iyong programa sa Outlook.
2. Pagkatapos sa pangunahing window ng Outlook, pindutin ang mga "Alt + F11" na mga shortcut sa key.
3. Kasunod, ang window na "Microsoft Visual Basic para sa Mga Aplikasyon" ay mag-pop up.
4. Susunod na kailangan mong buksan ang isang blangko na module at kopyahin ang mga sumusunod na VBA code dito.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Pagkatapos nito, kailangan mong tiyakin na pinahihintulutan ng iyong Outlook ang mga macros sa mga setting ng macro.
6. Sa paglaon, maaari kang magkaroon ng isang pagsubok.

• Una, bumalik sa bagong window ng macro.
• Susunod na pag-click sa "ExportFolderWithAllItems" subroutine.
• Pagkatapos ay pindutin ang F5 key button upang patakbuhin ang macro na ito.
• Pagkatapos nito, kailangan mong pumili ng isang tukoy na folder.
• Panghuli, kapag nakakuha ka ng isang mensahe na nagsasabing "Kumpleto", maaari mong ma-access ang paunang natukoy na lokal na folder. Mahahanap mo ang lahat ng mga item ay nai-save sa parehong istraktura ng folder.

Pigilan ang Pagkawala ng Data mula sa Mga Pag-crash ng Outlook

Marahil ay nakaranas ka na ng maraming pag-crash ng Outlook. Kadalasan, pagkatapos ng pag-restart, makakapagtrabaho nang normal ang Outlook. Gayunpaman, mayroon ding pagkakataon na maaaring masira ang ating PST file. Sa oras na iyon, susubukan mong makuha ang iyong PST data, tulad ng pag-ulit sa isang bihasang tool tulad ng DataNumen Outlook Repair. May kakayahang ayusin ang Outlook mga error at kunin ang data mula sa nakompromiso na file ng PST nang hindi pinagpapawisan.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang SQL Server magkumpuni at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa