Paano Mabilis na I-export ang Mga Detalye ng Lahat ng Miyembro sa isang Outlook Contact Group sa Excel

Bilang default, makikita mo lang ang mga pangalan ng miyembro at email address sa isang contact group. Kung nais mong makuha ang iba pang mga detalye ng mga miyembro, maaari mong gamitin ang paraan na ipinakilala sa artikulong ito.

Kapag nag-double click ka sa isang contact group upang buksan ito, sa window nito, makikita mo lamang ang mga pangalan at email address ng mga miyembro ng grupo. Hindi mo makuha ang iba pang mga detalye ng mga miyembro, tulad ng kumpanya, titulo ng trabaho, numero ng telepono o address ng negosyo, atbp. Sa pangkalahatan, upang makuha ang mga detalyeng ito, kailangan mong hanapin nang manu-mano ang mga contact na nauugnay sa mga miyembro sa iyong folder ng Mga Contact. Masyadong magulo. Dito ay ipapakita namin sa iyo ang isang piraso ng VBA code, na maaaring mabilis na ma-export ang mga detalyeng ito sa isang Excel workbook.

I-export ang Mga Detalye ng Lahat ng Miyembro sa isang Contact Group sa Excel

1. Para magsimula, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos ay dapat mong pindutin ang "Alt + F11" key shortcut sa pangunahing window ng Outlook.
3. Susunod sa bagong window ng "Microsoft Visual Basic for Applications", kailangan mong magbukas ng hindi ginagamit na module o direktang magpasok ng bagong module.
4. Kasunod, kopyahin at i-paste ang sumusunod na VBA code sa modyul na ito.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Pagkatapos nito, para sa maginhawang pagsusuri, maaari mong idagdag ang bagong proyekto ng VBA sa Quick Access Toolbar o ribbon.
6. Sa ibang pagkakataon, itakda ang iyong Outlook macro security level sa mababa.
7. Sa huli, maaari kang magkaroon ng isang pagsubok.

• Una, pumili ng isang contact group.
• Pagkatapos ay pindutin ang macro button sa Quick Access Toolbar o ribbon.
• Kaagad, tatakbo ang macro.
• Kapag natapos na ito, makakatanggap ka ng prompt ng "Kumpleto na!"
• Pagkatapos nito, maaari kang pumunta sa paunang natukoy na destinasyong lokal na folder, kung saan makakahanap ka ng bagong Excel file.
• Buksan ito, makikita mo ang mga detalye ng contact ng mga miyembro ng grupo tulad ng sumusunod na screenshot:

Huwag Magpanic sa Harap ng Mga Isyu sa Outlook

Walang handang tumanggap ng anumang mga problema sa Outlook, kahit na popup error message o sira ang Outlook file ng data. Samakatuwid, ang mga gumagamit ay may posibilidad na makakuha ng gulat kapag nakakaharap sa mga isyu sa Outlook. Kung gusto mong manatiling kalmado sa kasong iyon, dapat mayroon kang dalawang pangangailangan sa kamay. Ang isa ay kasalukuyang pag-backup ng data ng Outlook. Ang isa pa ay makapangyarihang Outlook fix software, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang sql paggaling at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa