Paano Mabilis na Maglakip ng Tiyak na Mga Slide ng a PowerPoint Pagtatanghal sa Iyong Email sa Outlook

Kung nais mong kunin ang mga tiyak na slide ng a PowerPoint pagtatanghal sa isang hiwalay na bagong pagtatanghal at ilakip ito sa isang email sa Outlook, maaari mong magamit ang paraang ibinahagi sa artikulong ito.

Sa halip na ikabit ang isang kabuuan PowerPoint pagtatanghal sa isang email, kung nais mong ikabit ang mga tukoy na slide ng pagtatanghal, sa pangkalahatan, kailangan mo munang kopyahin ang mga tukoy na slide sa isang bagong pagtatanghal. Ito ay masyadong mahirap. Samakatuwid, dito ipapakita namin sa iyo ang isang pamamaraan na maaaring mapagtanto ito nang sabay-sabay.

Ikabit ang Mga Tiyak na Slide ng a PowerPoint Pagtatanghal sa isang Email

1. Una, buksan ang tukoy PowerPoint Pagtatanghal.
2. Pagkatapos, sa PowerPoint window ng application, pindutin ang mga pindutan ng "Alt + F11" upang ma-access ang VBA editor.
3. Susunod, sa bagong window, lumikha ng isang bagong module sa pamamagitan ng pagpindot sa "Ipasok"> "Modyul".
4. Kasunod, kopyahin at i-paste ang sumusunod na VBA code sa modyul na ito.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Pagkatapos nito, maaari mong isara ang kasalukuyang window.
6. Mamaya, pumunta sa "File"> "Mga Pagpipilian"> "Quick Access Toolbar" upang idagdag ang bagong macro sa Quick Access Toolbar.
7. Panghuli, maaari mong subukan ang macro na ito.

• Bilang panimula, piliin ang mga partikular na slide na gusto mong i-extract.
• Pagkatapos, i-click ang pindutan ng macro sa Quick Access Toolbar.
• Kaagad, lalabas ang isang email sa Outlook, kung saan mayroong a PowerPoint pagtatanghal na nakuha mula sa pinagmulang pagtatanghal.

Gumamit ng isang Mabisang Tool sa Pag-recover

Tulad ng alam nating lahat, ang Outlook ay pinagkalooban ng built-in na utility sa pag-aayos - Scanpst. Gayunpaman, maaari lamang itong makayanan ang mga maliliit na glitches sa Outlook. Kung ang hinarap mo ay seryosong pinsala, hindi ito magbubunga. Sa puntong iyon, wala kang pagpipilian kundi magbalik sa isa pang makapangyarihang at mapagkakatiwalaang tool sa pag-aayos, tulad ng DataNumen Outlook Repair. Sa pamamagitan nito, magagawa mong i-save ang iyong nasirang file ng Outlook.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasira mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa