Paano Mabilis na Maglakip ng Mga Tiyak na Mga Pahina ng isang Word Document sa isang Outlook Email

Ang MS Word ay may direktang tampok na sumusuporta sa mga gumagamit upang maipadala ang kasalukuyang dokumento ng Word bilang isang kalakip na email. Ngunit kung minsan, maaari mo lamang asahan na ilakip ang mga tukoy na pahina ng isang dokumento ng Word sa isang email sa Outlook. Ngayon, magbabahagi sa iyo ang artikulong ito ng isang pamamaraan.

Upang magpadala ng isang buong dokumento ng Word bilang isang kalakip na email sa application ng MS Word, maaari kang pumunta lamang sa menu na "File" at ilipat sa tab na "I-save at Ipadala", kung saan maaari kang makahanap ng isang pindutang "Ipadala bilang Attachment". Gayunpaman, sa mga oras, ang nais mong ipadala ay maaaring mga tukoy na pahina lamang ng dokumento. Sa sitwasyong ito, maaari mong gamitin ang pamamaraang ipinakilala sa mga sumusunod upang magawa ito.

Ikabit ang Mga Tiyak na Pahina ng isang Word Document sa isang Email

1. Una, dapat mong buksan ang dokumento ng mapagkukunan ng Salita na ang mga tukoy na pahina na nais mong ipadala sa email.
2. Pagkatapos, pagkatapos makapasok sa window ng MS Word, kailangan mong pindutin ang mga pindutan ng "Alt + F11".
3. Susunod, makakakuha ka ng pag-access sa VBA editor sa MS Word.
4. Pagkatapos niyan, kailangan mong paganahin ang “Microsoft Outlook Object Library”. Maaari mong pindutin ang “Tools” > “Reference” para magawa ito.
5. Kasunod, dapat mong kopyahin ang sumusunod na VBA code sa isang module na hindi ginagamit.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Panghuli, maaari mong patakbuhin ang macro na ito. Pindutin lamang ang F5 key button o i-tap ang icon na "Run" sa toolbar.
7. Matapos ang makro na natapos, isang bagong email sa Outlook ang ipapakita, na naka-attach sa isang sipi ng pinagmulang dokumento ng Word, tulad ng sumusunod na screenshot:

I-extract ang Pinakamataas na Data mula sa Masirang Outlook File

Kung ginamit mo ang Outlook sa mga dekada, maaaring naharap ka sa iba't ibang mga isyu sa Outlook, kabilang ang mga popup panloob na mensahe ng error, biglaang pag-crash pati na rin ang seryosong pinsala sa file. Dahil sa katotohanan na ang Scanpst, nakapaloob na tool sa pag-aayos, makikitungo lamang sa maliliit na problema, mas mabuti mong mapanatili ang isang panlabas na makapangyarihang tool sa pag-aayos, sabihin DataNumen Outlook Repair. Nagagawa nitong maglabas ng maximum na data mula sa nasirang file ng data ng Outlook.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang sql ayusin at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa