Paano Mabilis na Maglakip ng Huling Binago na File sa isang Windows Folder sa Iyong Outlook Email

Sa mga oras, baka gusto mong mabilis na mahanap at ikabit ang huling binagong file sa isang tukoy na folder ng Windows sa isang email sa Outlook. Sa kasong ito, maaari mong gamitin ang pamamaraang ipinakilala sa artikulong ito.

Nais ng ilang mga gumagamit na mabilis na mahanap at maidagdag ng Outlook ang huling binagong file sa isang folder ng Windows sa isang email, tulad ng pinakahuling nilikha, binago o na-save na file. Gayunpaman, ang Outlook ay hindi nag-aalok ng ganitong direkta at katutubong tampok. Samakatuwid, sa mga sumusunod, ilalantad namin ang isang piraso ng VBA code, na madaling makakagawa nito.

Ikabit ang Huling Binago na File sa isang Windows Folder sa Email

1. Sa simula pa lamang, dapat mong ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos, pagkatapos mong makapasok sa pangunahing window ng Outlook, maaari mong pindutin ang mga pindutan ng "Alt + F11".
3. Susunod na maa-access mo ang window ng editor ng Outlook VBA sa tagumpay.
4. Kasunod, dapat mong hanapin at buksan ang isang module na hindi ginagamit.
5. At pagkatapos kopyahin at i-paste ang sumusunod na VBA code sa window ng module na ito.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Pagkatapos nito, maaari kang lumabas sa kasalukuyang window ng editor ng VBA at magpatuloy upang idagdag ang bagong macro sa Quick Access Toolbar o laso ng window ng Mensahe.
7. Sa paglaon kailangan mong baguhin ang antas ng iyong seguridad sa Outlook sa mababang.
8. Sa paglaon maaari kang magkaroon ng isang pagsubok.

• Una, lumikha at bumuo ng isang bagong email ng Outlook tulad ng dati.
• Pagkatapos ay pindutin ang pindutan ng macro sa Quick Access Toolbar, tulad ng imahe sa ibaba:
• Susunod hihilingin sa iyo na pumili ng isang mapagkukunang folder ng Windows at pindutin ang "OK".
• Kung may ganoong isang file sa napiling folder ng Windows, makakakuha ka ng isang prompt tulad ng sumusunod na screenshot:
• Kapag na-hit mo ang "Oo", ang file na ito ay agad na mai-attach.

Malutas ang Mga Problema sa Outlook sa lalong madaling panahon

Tuwing nakatagpo ka ng anumang mga isyu sa Outlook, inirerekumenda na malutas ang mga ito sa lalong madaling panahon. Sa sitwasyong ito, mas mabuti kang maghanda ng isang matatag Inaayos ang Outlook kasangkapan nang maaga, tulad ng DataNumen Outlook Repair. Ito ay may kakayahang ayusin ang mga error sa PST at mabigyang-save ang iyong data sa Outlook.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasira mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa