Paano Mabilis na Gumawa ng Contact Group mula sa Lahat ng Outlook Contacts na may Tukoy na Pamagat ng Trabaho

Upang mas madaling makipag-usap sa mga contact na may partikular na titulo ng trabaho, maaaring gusto mong mabilis na lumikha ng contact group mula sa mga contact na ito. Ngayon, sa artikulong ito, ibabahagi namin sa iyo ang isang mabilis na paraan.

Kung madalas kang magpapadala ng mga email, gawain o mga imbitasyon sa pagpupulong sa mga contact na may partikular na titulo sa trabaho, magiging mas maginhawa kung gagawa ka ng contact group mula sa kanila. Sa pangkalahatan, sa karaniwang paraan, kailangan mo munang lumikha ng bagong contact group at pagkatapos ay magdagdag ng mga contact sa grupo bilang mga miyembro nang paisa-isa. Medyo magulo. Samakatuwid, sa mga sumusunod, ituturo namin sa iyo ang isang mas mabilis na paraan upang makuha ito.

Gumawa ng Contact Group mula sa Lahat ng Contact na may Tukoy na Pamagat ng Trabaho

1. Sa una, sa isang folder ng Mga Contact, pumili ng contact na may partikular na titulo ng trabaho.
2. Pagkatapos, pindutin ang "Alt + F11" upang ma-access ang editor ng VBA ng Outlook.
3. Susunod, kopyahin ang sumusunod na VBA code sa isang blangkong module o proyekto.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Pagkatapos nito, ilipat ang cursor sa unang subroutine.
5. Panghuli, i-tap ang "F5" na key na button upang patakbuhin ang macro na ito.
6. Kapag nakumpleto ang macro, may lalabas na bagong contact group. Naglalaman ito ng lahat ng mga contact na may parehong titulo ng trabaho ng napiling contact sa Hakbang 1.

Mabisang Shieldin ang Data ng Outlook

Kahit na ang Outlook ay mayaman sa tampok, hindi nito maaalis ang katotohanan na ito ay mahina. Kaya, kung ayaw mong mawala ang iyong mahalagang data sa Outlook, kailangan mong magsikap na protektahan ito. Halimbawa, kailangan mong gumawa ng mga backup para sa data ng Outlook sa mga regular na pagitan. Gayundin, kung abot-kaya, inirerekumenda na magkaroon ng cutting-edge na tool sa pagkumpuni ng PST, tulad ng DataNumen Outlook Repair, Kung saan maaari ayusin ang PST data sa isang sandali.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasirang sql at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa