Paano Awtomatikong Gumamit ng Iba't ibang Kulay ng Font para sa Pagsagot at Pagpasa ng mga Email gamit ang Outlook VBA

Bilang default, hindi mo maaaring hayaan ang Outlook na awtomatikong gumamit ng iba't ibang kulay ng font para sa pagtugon at pagpapasa ng mga email. Samakatuwid, kung mayroon kang ganoong pangangailangan, maaari mong basahin ang post upang matuto ng matalinong diskarte.

Pinapahintulutan ka lang ng Outlook na tumukoy ng font na ginagamit para sa parehong pagtugon at pagpapasa ng mga email. Maaari kang pumunta sa “File” > “Options”. Pagkatapos, sa "Outlook Options", pumunta sa tab na "Mail" at i-click ang "Stationery and Fonts..." na buton. Sa kasunod na window, makikita mo ang button na "Font" sa "Pagtugon o pagpapasa ng mga mensahe". I-click ito, at pagkatapos ay maaari kang magtakda ng partikular na kulay ng font para sa pagtugon at pagpapasa ng mga email.

Gayunpaman, maraming user ang umaasa na gumamit ng iba't ibang kulay ng font para sa pagtugon o pagpapasa ng mga email. Kahit na ang Outlook ay hindi nagbibigay ng anumang mga direktang tampok para dito, maaari pa rin itong maisakatuparan gamit ang VBA code. Ngayon, basahin upang makakuha ng tulad ng isang piraso ng VBA code.

Awtomatikong Gumamit ng Iba't ibang Kulay ng Font para sa Pagsagot at Pagpasa ng mga Email

1. Para sa bilangtart, ilunsad ang application ng Outlook.
2. Pagkatapos, i-trigger ang VBA editor na may reference sa “Paano Patakbuhin ang VBA Code sa Iyong Outlook".
3. Susunod, alinsunod sa "Paano Magdagdag ng isang Object Library Sanggunian sa VBA", idagdag ang reference sa "MS Word Object Library ”.
4. Pagkatapos, kopyahin ang sumusunod na code sa proyektong "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Pagkatapos nito, restart Outlook upang buhayin ang macro na ito.
6. Panghuli, maaari kang magkaroon ng isang pagsubok.

• Pumili o magbukas ng isang email.
• Pagkatapos, i-click ang pindutang "Tumugon". Sa pagtugon sa email, maaari kang mag-type ng ilang salita sa katawan. Ang kulay ng font ay dapat na pink.
• O i-click ang "Reply All" na buton. Sa bagong "tumutugon sa lahat" na mail, maglagay ng mga salita sa katawan. Tiyak na berde ang kulay ng font.
• Katulad nito, i-click ang pindutang "Ipasa". Sa pagpapasa ng mail, ang mga bagong salita ay ipapakita sa asul.

Kumuha ng Recourse sa Maaasahang Software

Sa kaganapan ng Korapsyon sa Outlook, Most ang mga gumagamit ay may posibilidad na gumamit ng software sa pagbawi ng Outlook. Mayroong isang malaking halaga ng mga naturang programa na magagamit sa merkado. At ang ilan sa kanila ay kahit na walang bayad. Gayunpaman, dapat kang mag-ingat sa mga mula sa hindi kilalang mga mapagkukunan dahil maaari nilang palala at palala ang kasalukuyang kaso. Dapat kang tumulong sa isang maaasahang at may karanasang tool, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasirang sql at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa