Paano Auto Extract ang Mga Naka-embed na Larawan mula sa Mga Tukoy na Papasok na Email sa pamamagitan ng Outlook VBA

Kung gusto mong awtomatikong i-extract at i-save ng Outlook ang mga naka-embed na larawan mula sa mga partikular na papasok na email, maaari kang sumangguni sa artikulong ito. Dito ay ituturo namin sa iyo kung paano ito maisasakatuparan gamit ang VBA code.

Ang ilang mga gumagamit ay madalas na kailangang kunin ang mga naka-embed na larawan mula sa mga partikular na papasok na email at i-save ang mga ito sa isang partikular na folder ng Windows. Napakahirap na gawin iyon nang manu-mano sa bawat oras. Samakatuwid, marami ang umaasa sa pag-aaral ng mabilis at maginhawang diskarte upang hayaang awtomatikong magawa iyon ng Outlook. Ngayon, narito, ibabahagi namin sa iyo ang gayong pamamaraan.

Auto Extract Naka-embed na Mga Larawan mula sa Mga Partikular na Papasok na Email

1. Una, ilunsad ang iyong programa sa Outlook gaya ng dati.
2. Pagkatapos, i-trigger ang Outlook VBA editor gaya ng dati na may reference t “Paano Patakbuhin ang VBA Code sa Iyong Outlook".
3. Sa ibang pagkakataon, kopyahin at i-paste ang sumusunod na VBA code sa proyektong "ThisOutlookSession".

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Pagkatapos nito, mag-click sa subroutine na "Application_Startup".
5. Panghuli, i-click ang "F5" key upang ma-trigger ang macro na ito.
6. Mula ngayon, sa tuwing may darating na partikular na bagong email sa Inbox, mase-save ang mga naka-embed na larawan sa partikular na folder ng Windows, tulad ng ipinapakita sa sumusunod na screenshot.

Regular na linisin ang Malaking Attachment

Maipapayo na regular na linisin ang malalaking attachment mula sa iyong Outlook. Layunin nitong mapanatili ang tamang laki ng iyong Outlook file. Ang mas malaking Outlook file ay mas madaling masira. Gaya ng alam mo, ang pinsala sa PST ay medyo mahirap ayusin nang maayos. Marahil ay susubukan mo munang ayusin ito gamit ang inbox repair tool. Gayunpaman, sa karamihan ng mga kaso, hindi ito gagana. Ang tanging paraan mo lang ay isang dalubhasang... Pagkumpuni ng PST tool, tulad ng DataNumen Outlook Repair, o may kaugnayang propesyonal na mga serbisyo sa pagbawi.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mdf ayusin at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa