Paano Maantala ang Paghahatid sa isang Partikular na Miyembro kapag Nagpapadala ng Outlook Email sa isang Contact Group

Ang artikulong ito ay magbabahagi ng isang piraso ng VBA code, na maaaring magpapahintulot sa iyo na mabilis na maantala ang paghahatid sa isang partikular na miyembro kapag nagpapadala ng email sa isang contact group sa Outlook.

Kapag gumawa ka at nagpadala ng Outlook email sa isang contact group, kung gusto mong ipagpaliban ang pagpapadala ng email na ito sa isang partikular na miyembro sa grupong ito, maaari mong gamitin ang sumusunod na paraan upang maisakatuparan ito. Awtomatiko nitong palalawakin ang grupo ng contact at bubuo ng parehong email na naantala sa partikular na miyembro. Ngayon, basahin upang makuha ang detalyadong mga hakbang.

Iantala ang Paghahatid sa isang Partikular na Miyembro kapag Nagpapadala ng Email sa isang Contact Group

1. Para magsimula, ilunsad ang iyong programa sa Outlook.
2. Pagkatapos, sa umuusbong na pangunahing window ng Outlook, dapat mong pindutin ang mga pindutan ng "Alt + F11".
3. Sa dakong huli, makakakuha ka ng access sa Outlook VBA editor, kung saan kailangan mong magpasok ng bagong module o magbukas lang ng module na hindi ginagamit.
4. Pagkatapos nito, maaari mong kopyahin at i-paste ang sumusunod na VBA code sa modyul na ito.

Sub DelayEmail_aSpecificMemberinContactGroup()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objDelayedMail As MailItem
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact group in "To" field
          For i = objRecipients.count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend

    'Find the specific memebr in the recipients
    For Each objRecipient In objRecipients
        If objRecipient.Address = "shelly@datanumen.com" Then
 
           'Create a same email
           Set objDelayedMail = objCurrentMail.Copy
           With objDelayedMail
                .To = ""
                .Recipients.Add objRecipient.Address
                .Recipients.ResolveAll
                'Change the deferred delivery time as per your needs
                .DeferredDeliveryTime = (Date + 1) & " 09:00:00"
                .Send
          End With
 
          objRecipient.Delete
       End If
    Next
 
    objCurrentMail.Send
End Sub

5. Susunod, para sa madaling pag-access sa ibang pagkakataon, mas mabuting idagdag mo ang bagong idinagdag na macro sa Quick Access Toolbar ng window ng Mensahe.
6. At pagkatapos ay dapat mong baguhin ang iyong mga setting ng macro sa Outlook upang paganahin ang lahat ng mga macro sa "Mga Setting ng Macro" ng "Trust Center".
7. Sa paglaon, maaari kang kumuha ng isang shot.

• Una, gumawa ng naturang email sa pangkat ng contact gaya ng dati.
• Pagkatapos ay maaari mong i-click ang bagong macro button sa Quick Access Toolbar.
• Sabay-sabay, gagawa ng parehong email at itatakdang ipadala sa partikular na miyembro sa nakatakdang oras.
• Pansamantala, ang kasalukuyang email ay ipapadala sa iba pang miyembro sa contact group.

Abangan ang Lahat ng Panganib sa Iyong Outlook

Sa kasalukuyang panahon, ang mga virus at spyware ay lalong lumalaganap. Karaniwan itong nagkukunwaring mga hindi nakakapinsalang email. Kaya naman, dapat kang mag-ingat sa iba't ibang panganib sa iyong Outlook, tulad ng mga malisyosong email. Kailangan mong mag-ingat sa mga email mula sa mga hindi kilalang contact. Gayundin, upang ayusin ang Outlook sa sandaling maatake ng malware ang iyong PST file, kailangan mong maghanda ng isang bihasang tool sa pagkumpuni, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasirang sql at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa