Paano Ipadala ng Batch ang Lahat ng Worksheet sa Isang Excel Workbook bilang Mga Hiwalay na Outlook Email

Kung gusto mong ipadala ang lahat ng worksheet sa isang Excel workbook bilang hiwalay na mga email sa Outlook, maaari mong gamitin ang paraang ipinakilala sa artikulong ito. Maaari itong gabayan ka upang mapagtanto ito nang maramihan nang hindi mahirap na magpadala ng isa-isa.

Sa aking nakaraang post na "2 Mabilis na Paraan upang Magpadala ng isang Excel Worksheet bilang isang Outlook Email", maaari kang matuto ng dalawang paraan upang magpadala ng isang worksheet sa Excel bilang email. Kung nais mong ipadala nang batch ang lahat ng worksheet sa isang workbook bilang indibidwal na mga email, ang paggamit ng alinman sa dalawang paraang nabanggit sa post na iyon ay magiging medyo nakakapagod at nakakaabala. Kaya, ipapakilala namin dito ang isa pang paraan, na maaaring maisakatuparan ang ganitong "Batch Send" sa mabilis na panahon.

Batch Ipadala ang Lahat ng Worksheet sa Isang Excel Workbook bilang Mga Hiwalay na Email

1. Sa unang lugar, dapat mong buksan ang source Excel workbook.
2. Pagkatapos, pagkatapos na pumasok sa Excel window, dapat mong i-tap ang "Alt + F11" key shortcut.
3. Susunod, lalabas ang isa pang window na tinatawag na "Microsoft Visual Basic for Applications".
4. Sa loob nito, kailangan mong magbukas ng hindi nagamit na module o magpasok ng bagong module.
5. Kasunod, maaari mong kopyahin ang sumusunod na VBA code sa modyul na ito.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Pagkatapos nito, maaari mong i-trigger ang macro na ito sa pamamagitan ng pagpindot sa F5 key button o pag-click sa icon na "Run" sa toolbar.
7. Sabay-sabay, ang mga email, na tumutugma sa lahat ng worksheet sa Excel workbook na ito, ay ipapakita sa Outlook.
8. Sa wakas, maaari mong suriin muli ang lahat ng mga detalye ng email at sa wakas ay i-click ang "Ipadala" na buton upang ipadala ang mga email.

Mag-apply ng Potent Recovery Tool kung Walang Backup

Parami nang parami ang mga user na naiintindihan ang kahalagahan ng pag-backup ng data. Hangga't na-back up mo ang iyong PST file, Pagbawi ng PST pagkatapos ng pinsala ay magiging medyo simple. Ngunit kung walang epektibo at up-to-date na backup ng PST, wala kang pagpipilian kundi tumulong sa isang panlabas na tool sa pag-aayos ng PST, tulad ng DataNumen Outlook Repair. Maaari itong ayusin ang mga nakompromisong PST file na parang madali lang.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mabawi ang sql at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa