Paano Mag-grupo ng Paglipat ng Mga Email mula sa Lahat ng Mga Subfolder ng Isang Folder patungo sa Isa pang Folder sa Outlook

Marahil ay mayroon kang isang folder kung saan maraming mga subfolder. Kung nais mong ayusin muli ang mga email sa kanila, tulad ng mabilis na paglipat ng lahat ng mga email mula sa mga subfolder na ito sa isang tukoy na folder, maaari mong gamitin ang paraang ibinahagi sa artikulong ito.

Sa mga oras, maaaring kailanganin mong i-batch ang paglipat ng mga email mula sa lahat ng mga subfolder ng isang folder patungo sa isa pang folder para sa ilang kadahilanan, tulad ng nais mong muling uri-uriin ang mga email, kaya't ang mga subfolder na ito ay hindi na kapaki-pakinabang. Sa kasong ito, ang pagproseso ng mga subfolder na ito isa-isa ay medyo mahirap. Samakatuwid, dito ay ipakikilala namin sa iyo ng ibang paraan.

Batch Ilipat ang Mga Email mula sa Lahat ng Mga Subfolder ng Isang Folder patungo sa Isa pang Folder

1. Sa pinakasimula pa lang, simulan ang iyong programa sa Outlook.
2. Pagkatapos, sa pangunahing screen ng Outlook, mag-tap sa mga pindutang key ng "Alt + F11", na magdadala sa iyo sa VBA editor.
3. Susunod, sa bagong window na "Microsoft Visual Basic para sa Mga Aplikasyon", kailangan mong buksan ang isang module na hindi ginagamit.
4. Kasunod, kopyahin at i-paste ang sumusunod na VBA code sa modyul na ito.

Dim objTargetFolder As Outlook.folder

Sub BatchMoveEmailsFromSubfoldersToAnotherFolder()
    Dim objSourceFolder As Outlook.folder
    Dim objFolder As Outlook.folder
  
    'Get the source folder whose subfolders to be processed
    Set objSourceFolder = Application.Session.PickFolder
 
    If Not (objSourceFolder Is Nothing) And objSourceFolder.DefaultItemType = olMailItem Then
       If objSourceFolder.folders.count > 0 Then
          'Select a target folder
          Set objTargetFolder = Application.Session.PickFolder
          If Not (objTargetFolder Is Nothing) Then
             For Each objFolder In objSourceFolder.folders
                 Call ProcessFolders(objFolder)
             Next
             MsgBox "Move Completed!", vbExclamation
          End If
       Else
          MsgBox "No subfolders!", vbExclamation
       End If
    End If
End Sub

Sub ProcessFolders(ByVal objFolder As Outlook.folder)
    Dim i As Long
    Dim objSubfolder As Outlook.folder
 
    For i = objFolder.Items.count To 1 Step -1
        'Move emails to the target folder
        If objFolder.Items(i).Class = olMail Then
           objFolder.Items(i).Move objTargetFolder
        End If
    Next
 
    'Process subfolders recursively
    If objFolder.folders.count > 0 Then
       For Each objSubfolder In objFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Pagkatapos nito, maaari mong patakbuhin ang macro na ito.

• Una, sa macro window na ito, pindutin ang "F5" key button.
• Pagkatapos, kakailanganin kang pumili ng isang folder ng mapagkukunan na ang mga subfolder na iproseso.
• Pagkatapos nito, kailangan mong tukuyin ang patutunguhang folder kung saan mo nais ilipat ang mga email.
• Kasunod nito, magsisimulang gumana ang macro na ito. Kapag nakumpleto na ito, makakatanggap ka ng mensaheng nagsasabing "Kumpleto na".
• Sa huli, maaari mo nang ma-access ang target na folder. Makikita mo na ang lahat ng email ng mga subfolder sa ilalim ng source folder ay naroon.

Ibalik ang Kompromisong Data ng Outlook

Sa kabila ng pagmamalaki ng maraming tampok, tulad ng ibang mga email client, hindi pa rin makatakas ang Outlook mula sa katiwalian. Sa maraming at mas maraming data na nakaimbak, ang Outlook ay magiging madaling kapitan ng pagkakamali at pinsala. Samakatuwid, kailangan mong panatilihing madaling gamitin ang isang malakas na tool sa pag-aayos, tulad ng DataNumen Outlook Repair. Lalo na itong dinisenyo upang ayusin ang Outlook mga isyu. Sa gayon, maaari nitong i-scan at ibalik ang nasirang file ng Outlook nang walang kahirap-hirap.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mdf paggaling at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datKanumen.com