Paano Batch I-export ang Lahat ng mga Email sa isang pag-uusap bilang Mga Text File sa pamamagitan ng Outlook VBA

Minsan, baka gusto mong i-batch ang makuha ang lahat ng mga email sa isang tukoy na pag-uusap at pagkatapos i-export ang mga ito sa lokal na folder bilang mga Text file. Ituturo sa iyo ng artikulong ito kung paano makuha ito sa mabilis na oras.

Para sa ilang kadahilanan, maaaring kailanganin mong i-export ang lahat ng mga email sa isang tiyak na pag-uusap sa iyong lokal na drive. Kung manu-manong gawin mo ito, lalo na ang paghanap at pag-save ng isa-isa, ito ay magiging isang nakakapagod at mahirap na gawain. Samakatuwid, mas mabuti kang maghanap ng iba pang mas mabilis na pamamaraan, tulad ng sumusunod. Gumagamit ito ng isang piraso ng VBA code upang makuha ito nang hindi pinagpapawisan.

I-export ang Batch Lahat ng Mga Mails sa isang pag-uusap bilang Mga Text File

1. Sa simula pa lamang, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos ay pindutin ang "Alt + F11" mga pindutan ng key upang ma-access ang editor ng VBA ng Outlook.
3. Kasunod, sa bagong window, kailangan mong buksan ang isang module na hindi ginagamit o direktang ipasok ang isang bagong module.
4. Susunod dapat mong kopyahin at i-paste ang mga sumusunod na VBA code sa modyul na ito.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Pagkatapos nito, maaari mong idagdag ang bagong proyekto ng VBA sa Quick Access Toolbar tulad ng dati.
6. Mamaya tiyaking mababa ang antas ng iyong seguridad ng Outlook.
7. Panghuli, maaari kang magkaroon ng isang pagsubok.

• Una, pumili ng isang email.
• Pagkatapos i-click ang bagong pindutan ng macro sa Quick Access Toolbar.
• Kapag nakuha mo ang mensahe na "Kumpleto", maaari mong buksan ang paunang natukoy na lokal na folder, kung saan makikita mo ang mga email sa format na "TXT".

Mga tip para sa Pagpapanumbalik ng Data ng PST pagkatapos ng Korapsyon

Kadalasan, sa Outlook, maaari kang makatagpo ng iba't ibang mga error sa Outlook, ang ilan sa mga ito ay maaaring maging malubhang seryoso upang deretso silang humantong sa katiwalian sa PST. Sa oras na iyon, kailangan mong gumawa ng mga aksyon ayusin ang PST file upang malaman muli ang iyong mahalagang data. Sa kasong ito, maaari mo lamang ulitin ang isang kagalang-galang at napatunayan nang mahusay na tool, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mabawi sql server at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa