6 Mga Paraan upang mapanatili ang Orihinal na Mga Attachment ng Email kapag Tumugon sa Outlook

Maraming mga gumagamit ang umaasa na mai-configure ang kanilang Outlook upang mapanatili ang orihinal na mga kalakip na email kapag tumutugon ng isang email. Ilalantad sa artikulong ito ang 5 mga pag-iingat pati na rin ang isang matalinong paraan, na gumagamit ng VBA upang awtomatikong mapagtanto ito.

Narinig ko ang isang mahusay na bilang ng mga gumagamit na nagreklamo na ang Outlook ay walang isang katutubong tampok upang mapanatili ang mga orihinal na attachment kapag tumutugon ng isang email. Samakatuwid, dito ibabahagi namin sa iyo ang 6 na pamamaraan, ang isa sa mga ito ay lubos na kapaki-pakinabang dahil gumagamit ito ng VBA upang gawing awtomatikong ikabit ng Outlook ang mga orihinal na attachment sa pagtugon ng email. Ngayon basahin upang makuha ang mga ito nang detalyado.

1. Tumugon na may Nakalakip na Orihinal na Email

Bagaman hindi nagbibigay ang Outlook ng isang tampok para sa pagpapanatili ng mga orihinal na attachment ng email kapag tumutugon ng isang email, pinapayagan nito ang mga gumagamit na panatilihing nakakabit ang orihinal na email. Samakatuwid, ito ay isang opsyonal na solusyon para sa iyo. Maaari kang magtungo sa seksyong "File"> "Mga Pagpipilian"> "Mail"> seksyon na "Tumutugon at pasulong" upang baguhin ang mga setting ng tugon. Para sa karagdagang detalye, iminungkahi para sa iyo na mag-refer sa aking nakaraang artikulo - “5 Mga Hakbang upang Tumugon sa Orihinal na Mga Attachment sa Outlook". Ngunit, kung umaasa ka pa ring panatilihin lamang ang mga orihinal na attachment, magpatuloy upang malaman ang iba pang mga paraan.

2. Manu-manong I-drag at I-drop ang Mga Attachment

1. Para magsimula, i-double click ang naturang source email para buksan ito sa sarili nitong window.
2. Pagkatapos ay i-click ang pindutang "Tumugon", na magbibigay ng email sa pagtugon.
3. Susunod dapat mong pag-urong ang parehong mga window ng Mensahe hanggang sa makita mo sila sa parehong screen.
4. Pagkatapos nito, piliin ang lahat ng mga kalakip sa orihinal na email.
5. Panghuli, i-drag at i-drop ang mga ito sa linya na "Nakalakip" sa pagtugon sa email.

3. Manu-manong Kopyahin at I-paste ang Mga Attachment

1. Sa unang lugar, pagkatapos buksan ang mapagkukunang email, piliin ang lahat ng mga kalakip.
2. Pagkatapos i-click ang pindutang "Kopyahin" sa ilalim ng tab na "Mga Attachment".
3. Pagkatapos nito, i-click ang pindutang "Tumugon" sa ilalim ng tab na "Mensahe" upang buksan ang isang sumasagot na mail.
4. Sa huli, sa email na tumutugon, mag-click sa linya na "Nakalakip" at pindutin ang pindutan na "Ctrl + V" upang i-paste ang dating kinopyang mga kalakip.

4. Ipasa ang Email at Punan ang Tatanggap

1. Una, piliin ang naturang email at pagkatapos ay i-click ang pindutang "Ipasa" sa laso.
2. Sa bagong popup window ng Mensahe, itinatago ang mga orihinal na attachment. Ngayon ay kailangan mong punan ang patlang na "To" sa nagpadala ng orihinal na email.
3. Bilang pagpipilian, maaari mong baguhin ang paksa alinsunod sa iyong mga pangangailangan.

5. Ipadala muli ang Email at Baguhin ang Mga Tatanggap

1. Upang magsimula sa, buksan ang email ng mapagkukunan.
2. Pagkatapos i-click ang pindutang "Mga Pagkilos" sa pangkat na "Ilipat".
3. Susunod na piliin ang "Ipadala muli ang Mensahe na Ito" mula sa drop down na listahan.
4. Marahil ay makakakuha ka ng isang alerto na binabanggit na hindi ka ang orihinal na nagpadala. Balewalain lamang ito at pindutin ang "Oo".
5. Sa kasunod na bagong email, dapat mong baguhin ang patlang na "To" sa nagpadala ng orihinal na email.
6. Gayundin, tandaan na baguhin ang ipadala gamit ang email account sa iyong sariling account.

6. Auto Magdagdag ng Orihinal na Mga Attachment sa pamamagitan ng VBA

Ang lahat ng mga pamamaraang nabanggit sa itaas, upang maging matapat, ay mga workaround. Kung inaasahan mong awtomatikong mapapanatili ng Outlook ang mga orihinal na attachment kapag tumutugon, maaari mong gamitin sa ganitong paraan.

1. Sa pangunahing window ng Outlook, pindutin ang mga pindutan ng "Alt + F11".
2. Pagkatapos, sa window na "Microsoft Visual Basic for Applications", kopyahin ang VBA code sa ibaba sa proyekto na "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Mamaya lagdaan ang macro na ito at baguhin ang iyong mga setting ng macro ng Outlook upang pahintulutan ang mga naka-sign na macros.
4. Pagkatapos nito, i-restart ang iyong Outlook application upang i-activate ang VBA project na ito.
5. Mula ngayon, sa bawat oras na mag-click sa pindutang "Tumugon". Ipapakita ang pagsagot ng email na may mga orihinal na kalakip nang sabay-sabay.

Resort sa isang Pinakamahalagang Tool sa Pag-ayos

Inakbayan ng Outlook ang iba pang mga kliyente sa email dahil sa maraming mga tampok nito. Ngunit ito ay madaling kapitan ng sakit sa katiwalian. Samakatuwid, dapat kang magbayad ng higit na pansin sa kalusugan nito. Sa pangkalahatan, kapag nakakaranas ng maliliit na isyu, maaari mo lamang ulitin ang built-in na utility na pag-aayos. Gayunpaman, kung nagdusa ka ng mga malubhang problema, mas mabuti kang umulit sa isang mas mahusay na tool, tulad ng DataNumen Outlook Repair. Maaari ito ayusin ang Outlook mag-file sa isang iglap.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang sql ayusin at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa