2 Mabilis na Mga Paraan upang Mag-extract ng Mga Seksyon mula sa Iyong Dokumento ng Salita

Sa artikulong ito, mag-aalok kami sa iyo ng 2 mabilis at madaling paraan upang kumuha ng mga seksyon mula sa iyong dokumento sa Word sa isa pa o marami.

Madalas itong nangyayari upang kumuha ng mga nilalaman mula sa isang dokumento patungo sa isa pa. At sa aming nakaraang artikulo, tinalakay namin kung paano kumuha ng mga pahina mula sa dokumento. Para sa detalyadong impormasyon, maaari kang mag-refer sa artikulong ito: 2 Mabilis na Mga Paraan upang Kumuha ng Indibidwal na Mga Pahina mula sa Iyong Dokumentong Word

Ngayon, ipapakita namin sa iyo kung paano kumuha ayon sa seksyon.    

Paraan 1: Kumuha ng Kasalukuyang Seksyon sa isang Bagong Dokumento

1. Una sa lahat, ilagay ang cursor sa isang target na seksyon.
2. Susunod na pindutin ang "Alt + F11" upang ipatawag ang VBA editor sa Word.
3. Pagkatapos sa kaliwang haligi, mag-click sa "Normal".
4. At sa menu bar, i-click ang "Ipasok".
5. Pagkatapos piliin ang "Modyul" sa drop-down na menu na iyon.
6. I-double click upang buksan ang bagong module at i-paste ang mga sumusunod na code doon:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Susunod, i-click ang "Run" sa menu bar o pindutin ang "F5".
8. Pagkatapos ay pop up ang window na "Mag-browse". Pumili ng isang lugar upang maiimbak ang bagong dokumento at i-click ang "OK".
9. At sa kahon na "Pangalan ng File", ipasok ang pangalan para sa bagong file at i-click ang "OK".

Ngayon ay nakuha mo ang seksyon sa isang bagong dokumento.

Paraan 2: Kinuha ang Bawat Seksyon sa Dokumento sa Indibidwal na Mga Bagay

Ang ganitong paraan ay makakatulong sa iyo na iproseso ng batch ang lahat ng mga seksyon sa isang dokumento. Siyempre, kakailanganin din namin ng isang macro.

1. Upang magsimula, buksan ang target na dokumento.
2. Pagkatapos ay sundin ang mga hakbang sa pamamaraan 1 upang mai-install at magpatakbo ng isang macro.
3. Sa oras lamang na ito palitan ang macro na ito sa isang ito:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Gayunpaman, sa window na "Mag-browse", pumili ng isang path ng imbakan at i-click ang "OK".

Ayusin ang Mga Nakagagalit na Mga Error sa Salita

Karaniwan na mahahanap ang ilang mga pagkakamali sa Word habang ginagamit ito. Nakakainis na ito, kailangan nating maglaan ng oras mabawi ang salita sa madaling panahon. Dahil kung mas matagal natin ito, mas masahol ang pagkawala ng data. Samakatuwid, iminungkahi na humawak nang maaga sa isang pag-aayos ng utility.

Panimula ng May-akda:

Si Vera Chen ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasira xls at pdf pagkumpuni ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa