หากคุณต้องการส่งออกอีเมล Outlook หลายฉบับเป็นชุดเป็นเอกสารคำเดียวคุณสามารถใช้รหัส VBA ที่แสดงในบทความนี้ สามารถช่วยให้คุณทำงานนี้ให้สำเร็จได้ภายในไม่กี่วินาที
ฉันเคยแนะนำวิธีการแปลงอีเมล Outlook เป็นเอกสาร Word ในบทความก่อนหน้านี้ -“2 วิธีที่มีประสิทธิภาพในการแปลงอีเมล Outlook เป็นเอกสาร Wordอย่างไรก็ตาม วิธีการทั้งสองที่กล่าวถึงในโพสต์นั้นจะใช้ไม่ได้ผลในกรณีที่คุณต้องการส่งออกอีเมลจำนวนมากไปยังเอกสาร Word เดียว ดังนั้น ในที่นี้เราจะสอนวิธีการอื่นให้คุณ โปรดอ่านต่อเพื่อเรียนรู้รายละเอียดเพิ่มเติม
ชุดส่งออกอีเมล Outlook หลายฉบับเป็นเอกสาร Word เดียว
- ขั้นแรก ให้เปิดโปรแกรม Outlook ของคุณ
- จากนั้นหลังจากเข้าสู่หน้าต่างหลักของ Outlook คุณจะต้องกดปุ่ม "Alt + F11"
- ถัดไปคุณจะสามารถเข้าถึงโปรแกรมแก้ไข Outlook VBA ซึ่งคุณควรเปิดโมดูลเปล่า
- จากนั้นคัดลอกรหัส VBA ด้านล่างลงในหน้าต่างโมดูลที่เปิดอยู่
Sub ExportMultipleEmails_OneWordDocument()
Dim objFileSystem As Object
Dim strTempFolder As String
Dim objSelection As Outlook.Selection
Dim objMail As Outlook.MailItem
Dim strFileName As String
Dim objWordApp As Word.Application
Dim objNewWordDocument As Word.Document
Dim objWordRange As Word.Range
Dim strWordDocument As String
Dim i As Long
'Create a temp folder
Set objFileSystem = CreateObject("Scripting.FileSystemObject")
strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
MkDir (strTempFolder)
On Error Resume Next
'Save each selected email as an individual Word document in a temp folder
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For Each objMail In objSelection
strFileName = objMail.Subject
'Remove the unsupported characters in email subject
strFileName = Replace(strFileName, "/", " ")
strFileName = Replace(strFileName, "\", " ")
strFileName = Replace(strFileName, ":", "")
strFileName = Replace(strFileName, "?", " ")
strFileName = Replace(strFileName, Chr(34), " ")
objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
Next
'Merge all the Word documents into a single document
Set objWordApp = CreateObject("Word.Application")
Set objNewWordDocument = objWordApp.Documents.Add
strWordDocument = Dir(strTempFolder & "\" & "*.doc")
i = 0
Do Until strWordDocument = ""
i = i + 1
Set objWordRange = objNewWordDocument.Range
With objWordRange
.Collapse wdCollapseEnd
If i > 1 Then
.InsertBreak wdSectionBreakNextPage
.End = objNewWordDocument.Range.End
.Collapse wdCollapseEnd
End If
.InsertFile strTempFolder & "\" & strWordDocument
End With
strWordDocument = Dir()
Loop
'Change the path as per your own needs
objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
objWordApp.Quit
'Delete the temp folder
objFileSystem.DeleteFolder (strTempFolder)
End Sub
- หลังจากนั้นคุณควรเพิ่มโปรเจ็กต์ VBA ใหม่นี้ลงในแถบเครื่องมือด่วนหรือริบบิ้น
- ในที่สุดคุณสามารถลอง
- ในตอนแรกให้เลือกอีเมล Outlook หลายฉบับ
- จากนั้นค้นหาและคลิกที่ปุ่มมาโครที่เพิ่มเข้ามาใหม่
- หลังจากที่คุณได้รับข้อความ“ เสร็จสมบูรณ์” คุณสามารถเรียกดูโฟลเดอร์ภายในเครื่องที่กำหนดไว้ล่วงหน้าเพื่อค้นหาเอกสาร Word ใหม่
- เปิดเอกสารนี้ซึ่งคุณจะเห็นอีเมลที่เลือกทั้งหมดถูกส่งออก
เก็บเครื่องมือการกู้คืนอันยิ่งใหญ่ไว้ใกล้ ๆ
โดยไม่คำนึงถึงฟังก์ชันต่างๆมากมาย Outlook ยังคงไม่สามารถป้องกันจากข้อผิดพลาดได้ หากคุณคุ้นเคยกับการปล่อยให้ข้อผิดพลาดอยู่คนเดียวโดยที่พวกเขาซ้อนกัน Outlook จะหยุดทำงานอย่างแน่นอน เมื่อถึงจุดนั้นจำเป็นอย่างยิ่งที่จะต้องใช้เครื่องมือการกู้คืนที่ทรงพลังและมีประสิทธิภาพอีกครั้งเช่น DataNumen Outlook Repair. มีความเชี่ยวชาญเป็นอย่างดี PST แก้ไข. ตราบใดที่คุณไม่ต้องกังวลเกี่ยวกับการสูญเสียข้อมูล Outlook อีกต่อไป
บทนำผู้เขียน:
Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ mdf เสียหาย และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.