วิธีการส่งออกสถิติการโหวตอย่างรวดเร็วจากอีเมล Outlook ไปยังแผ่นงาน Excel

หากคุณส่งอีเมลพร้อมปุ่มลงคะแนนหลังจากที่ผู้รับส่งการตอบกลับคุณอาจต้องการนับและส่งออกสถิติการลงคะแนนไปยังแผ่นงาน Excel ดังนั้นในหน้านี้ostเราจะสอนวิธีบรรลุผลอย่างรวดเร็ว

Outlook มีประสิทธิภาพมากถึงขนาดมีคุณลักษณะ "การโหวต" บทความก่อนหน้าของฉัน“การใช้ MS Outlook อย่างมีทักษะในการลงคะแนน” ได้สอนวิธีใช้อย่างมีประสิทธิภาพ นอกจากนี้มost หลังจากการลงคะแนนคุณสามารถดำเนินการส่งออกสถิติการลงคะแนนไปยังแผ่นงาน Excel ได้ด้วยเหตุผลบางประการเช่นต้องการพิมพ์สถิติ แต่ Outlook ไม่สนับสนุนสิ่งนี้โดยค่าเริ่มต้น ดังนั้นในขั้นตอนต่อไปนี้เราจะสอนวิธีการตระหนักถึงสิ่งนี้เหมือนไม้ก๊อก

ส่งออกสถิติการโหวตในอีเมลไปยังแผ่นงาน Excel

1. ในตอนแรกให้เปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นคุณควรกดปุ่ม“ Alt + F11” ในหน้าต่างหลักของ Outlook
3. ถัดไปในหน้าต่าง“ Microsoft Visual Basic for Applications” คุณควรเปิดใช้งาน“ Microsoft Excel Object Library”. คลิก "เครื่องมือ"> "ข้อมูลอ้างอิง" จากนั้นในกล่องโต้ตอบป๊อปอัปให้ทำเครื่องหมายที่ช่องหน้า“ Microsoft Excel Object Library” และกด“ ตกลง” ในที่สุด
4. หลังจากนั้นคุณสามารถแทรกโมดูลใหม่หรือเปิดโมดูลที่ไม่ได้ใช้งาน
5. จากนั้นคัดลอกและวางรหัส VBA ต่อไปนี้ลงในโมดูลนี้

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. หลังจากนั้นเพื่อความสะดวกคุณควรเพิ่มมาโครใหม่ลงในแถบเครื่องมือด่วน
6. ในที่สุดคุณสามารถลอง

• อันดับแรกเลือกอีเมลต้นทางที่มีปุ่มโหวต
• จากนั้นคลิกปุ่มมาโครในแถบเครื่องมือด่วน
• หลังจากแมโครนี้ทำงานเสร็จคุณสามารถเรียกดูโฟลเดอร์ภายในเครื่องที่กำหนดไว้ล่วงหน้าซึ่งคุณจะเห็นเวิร์กบุ๊ก Excel ใหม่
• เปิดสมุดงาน Excel นี้ ตอนนี้คุณจะเห็นสถิติการโหวตดังภาพด้านล่าง:

ไม่มีใครสามารถหลีกเลี่ยงข้อผิดพลาดของ Outlook ได้อย่างทั่วถึง

แม้ว่า Outlook จะมาพร้อมกับความสามารถที่หลากหลาย แต่ก็ไม่มีคุณลักษณะดังกล่าวที่จะช่วยให้เราหลีกเลี่ยงข้อผิดพลาดของ Outlook ได้ ปัจจัยทุกประเภทอาจทำให้เกิดข้อผิดพลาดของ Outlook ตัวอย่างเช่นหากคุณมักจะออกจาก Outlook อย่างไม่ถูกต้องคุณอาจจะต้องทนทุกข์ทรมาน ปส. ทุจริต. ในสถานการณ์เช่นนี้คุณไม่มีทางเลือกอื่นนอกจากใช้เครื่องมือที่มีศักยภาพบางอย่างเพื่อช่วยเหลือไฟล์ PST ของคุณเช่น DataNumen Outlook Repair. ได้รับความชื่นชอบมากมายเนื่องจากมีอัตราการฟื้นตัวสูง

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ mdf เสียหาย และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.