Как быстро экспортировать общее время, затраченное на встречи Outlook в каждой цветовой категории

Если вы хотите создать отчет об общем времени, которое вы тратите на встречи в каждой цветовой категории, вы можете использовать метод, представленный в этой статье. Это может помочь вам выполнить это в кратчайшие сроки без необходимости подсчета вручную.

Многие пользователи привыкли регистрировать большую часть своей активности в календаре Outlook. Кроме того, для более удобного управления и различения событий они присваивают каждому из них категории. В этом случае некоторым пользователям хотелось бы создавать отчет, показывающий общее время, затраченное на события календаря в каждой цветовой категории. Безусловно, подсчет и ввод данных вручную — это трудоемкий процесс. Поэтому здесь мы расскажем о способе, который позволит выполнить эту задачу одним простым щелчком мыши.

Экспорт общего времени, затраченного на встречи в каждой цветовой категории

1. Прежде всего, запустите приложение Outlook.
2. Затем, после входа в окно Outlook, вы можете нажать на клавиши «Alt + F11».
3. Впоследствии вы получите доступ к окну «Microsoft Visual Basic для приложений».
4. Далее вам потребуется включить «Библиотеку объектов Microsoft Excel». Для этого можно щелкнуть «Инструменты» > «Ссылки».
5. Затем вам нужно найти и открыть модуль, который не используется.
6. После этого вам нужно скопировать следующий код VBA в этот модуль.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Наконец, вы можете запустить этот макрос, щелкнув значок «Выполнить» на панели инструментов или нажав кнопку «F5».
8. Затем вам будет предложено выбрать конкретный календарь.
9. После того, как вы выберете и нажмете «ОК», макрос продолжит работу. После завершения появится новый файл Excel, который будет отображаться в фоновом режиме.
10. Вы можете получить к нему доступ. Это будет выглядеть как на следующем скриншоте:

Следите за потенциальными угрозами вокруг вашего Outlook

Пользователи Outlook должны следить за всеми потенциальными рисками, включая неизвестные вложения электронной почты, встроенные ссылки и человеческие ошибки. В противном случае ваш Outlook может быть поврежден в любое время. Кроме того, необходимо регулярно делать резервные копии данных Outlook и использовать специализированный инструмент для восстановления. DataNumen Outlook Repair Это один из наиболее рекомендуемых инструментов для устранения неполадок. Он может восстановить Outlook проблемы в один миг.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая поврежденный мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com