Как экспортировать структуру папок вашего файла Outlook в Excel

Если вы хотите быстро экспортировать структуру папок файла данных Outlook в книгу Excel, вы можете использовать метод, представленный в этой статье.

По некоторым причинам, таким как регистрация текущих папок и подпапок Outlook, многие пользователи надеются экспортировать структуру папок файла Outlook во внешний файл, например книгу Excel. Далее мы поделимся с вами фрагментом кода VBA, который поможет вам добиться этого в один миг.

Экспорт структуры папок вашего файла Outlook в Excel

1. К start с, запустите приложение Outlook.
2. Затем в главном окне Outlook нажмите клавиши «Alt + F11».
3. Далее вы попадете в редактор Outlook VBA, в котором вам нужно открыть неиспользуемый модуль.
4. Впоследствии вы можете скопировать следующий код VBA в этот модуль.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. После этого вы должны убедиться, что в Outlook включены макросы.
6. В конце концов, вы можете сделать снимок:

• В текущем окне макроса нажмите клавишу F5.
• После завершения макроса вы получите предупреждение «Завершено».
• Позже вы можете перейти в предопределенную локальную папку, чтобы найти новый файл Excel. Откройте его, и он будет выглядеть следующим образом:

Никогда не игнорируйте ошибки Outlook

Несмотря на множество возможностей, Outlook так же подвержен ошибкам и повреждениям, как и другие почтовые клиенты. Поэтому вы должны придавать значение всем ошибкам в вашем Outlook. Не пренебрегайте ими, пожалуйста. В противном случае накопление ошибок может в конечном итоге привести к повреждению Outlook. При столкновении с запутанными ошибками предлагается использовать мощный инструмент, такой как DataNumen Outlook Repair, Которые могут восстановить Outlook ошибки за секунды.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая sql восстановление и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com