Как пакетно отправить все файлы в папке Windows через отдельные электронные письма Outlook

Если вы хотите отправить кому-то все файлы в папке Windows через отдельные электронные письма Outlook, вы можете использовать метод, представленный в этой статье. Он использует код VBA, что весьма эффективно.

Прочитав мою предыдущую статью — «3 быстрых способа прикрепить все файлы в локальной папке к электронному письму Outlook», некоторые пользователи хотят отправлять все файлы в локальной папке по отдельным электронным письмам. Стандартным образом вы должны создавать электронные письма и прикреплять файлы один за другим. Это довольно хлопотно. Поэтому в дальнейшем мы представим вам более эффективный способ.

Пакетная отправка всех файлов в папке Windows по отдельным электронным письмам

1. Для начала запустите программу Outlook.
2. Затем в Outlook откройте редактор VBA со ссылкой на статью — «Как запустить код VBA в Outlook».
3. Затем скопируйте и вставьте следующий код VBA в проект или модуль.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

4. После этого вы можете сразу запустить этот макрос. Просто нажмите кнопку «F5».
5. Впоследствии вам потребуется выбрать исходную папку Windows во всплывающем диалоговом окне.
6. В конечном итоге Outlook прикрепит все файлы в этой папке Windows к отдельным электронным письмам и отправит письма заранее определенному получателю.
7. Когда он завершится, вы получите сообщение «Все готово!».

Следите за здоровьем Outlook

Хотя Outlook позиционируется как самый популярный почтовый клиент на рынке, у него всё же есть фатальный недостаток. Это его уязвимость. Другими словами, Outlook подвержен различным ошибкам и повреждению. Поэтому необходимо уделять большое внимание состоянию Outlook, защищая его от повреждений. Кроме того, следует регулярно создавать резервные копии файлов Outlook. Также рекомендуется использовать инструмент для восстановления PST-файлов, например, DataNumen Outlook Repair. Он может восстановить Outlook вопросы без проблем.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая исправление sql и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com