Как пакетно удалить все адреса электронной почты с определенным доменом из ваших контактов Outlook

Иногда вам может понадобиться удалить из контактов все адреса электронной почты с определенным доменом. В такой ситуации вы, вероятно, не захотите делать это по одному адресу. Поэтому в этой статье мы расскажем вам о гораздо более эффективном методе.

Например, компания меняет название. Между тем, домен компании также изменяется. Однако в Outlook вы сохранили много контактов в этой компании, адреса электронной почты которых находятся со старым доменом. Конечно, эти адреса электронной почты больше недействительны. Следовательно, в этом случае, если вы хотите удалить эти адреса электронной почты за один раз, вы можете использовать следующий способ.

Пакетное удаление всех адресов электронной почты с определенным доменом из контактов

1. Для начала откройте редактор VBA в Outlook с помощью сочетания клавиш — «Alt + F11».
2. Затем в новом окне поместите следующий код VBA в пустой модуль.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. После этого установите курсор в подпрограмме «BatchRemoveAllEmailAddressesInSpecificDomain».
4. Наконец, нажмите кнопку «F5», чтобы запустить этот макрос.
5. Затем введите конкретный домен во всплывающем диалоговом окне.
6. После нажатия «ОК» макрос запустится.
7. Когда он завершится, вы получите сообщение о результатах.
8. Теперь вы можете проверить контакты. Все адреса электронной почты с определенным доменом должны были исчезнуть.

Сохраните файл Outlook

Чем больше рисков окружает ваш Outlook, тем сложнее защитить ваши ценные данные Outlook. Например, вы должны не только регулярно выполнять резервное копирование данных, но и следить за своими операциями. Неразумно с готовностью доверять любым электронным письмам от неизвестных отправителей. В противном случае, если он содержит вирус, ваш файл Outlook будет заражен. В это время вы должны попытаться Восстановление Outlook с помощью замечательного инструмента исправления, такого как DataNumen Outlook Repair.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая оправляться Sql Server и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com