3 способа быстро вставить разрывы разделов в документ Word

В этой статье мы сосредоточимся на том, чтобы показать вам 3 способа быстрой вставки разрывов разделов в документ Word.

Разрывы разделов полезны для разделения документа на разделы, главы и т. д. Кроме того, вставка разрывов разделов является неотъемлемой частью настройки разных верхних или нижних колонтитулов на разных страницах.

Обычно нам нужно будет перейти на страницу и установить курсор в нужное место. Затем нажмите «Разметка страницы» и «Разрывы». Затем выберите тип разрыва раздела в раскрывающемся меню. Такая процедура иногда может быть утомительной. Поэтому мы хотим избавить вас от привычной рутины и принять быстрое и грязное решение.

Способ 1: вставить разрыв раздела на определенной странице

1. Прежде всего, нажмите «Alt + F11» в Word, чтобы вызвать редактор VBA.
2. Затем создайте новый модуль, нажав «Обычный» в левом столбце.
3. Затем нажмите вкладку «Вставить» в строке меню.
4. И выберите «Модуль» в раскрывающемся меню «Вставить».
5. Дважды щелкните новый модуль, чтобы открыть его.
6. Вставьте следующий макрос в область кодирования:

Sub InsertBreakOnSpecificPage()
  Dim strPageNum As String
  Dim nPageNum As Integer
 
  strPageNum = InputBox("Enter a page number: ")
  nPageNum = Int(strPageNum)
 
  Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nPageNum
  ActiveDocument.Bookmarks("\page").Range.Select
  Selection.Collapse wdCollapseEnd
  Selection.InsertBreak Type:=wdSectionBreakContinuous
End Sub

7. Теперь нажмите «Выполнить» или нажмите «F5», чтобы выполнить коды.
8. Затем введите номер страницы tarполучить страницу в поле подсказки. И нажмите «ОК», чтобы продолжить.

До сих пор вы вставляли разрыв раздела в конце страницы 2.

Внимание:

Если вы хотите разделить несколько последовательных страниц в виде раздела с использованием разрывов раздела, вам нужно вставить разрыв раздела дважды, один раз в конце последней страницы предыдущего раздела и один в конце последней страницы этого нового раздела. .

В таком случае, вставляя первый разрыв, вы должны помнить о вводе правильного числа, которое является номером страницы последней страницы предыдущего раздела.

Способ 2: вставить разрыв раздела на каждой странице документа

1. Во-первых, установите и запустите макрос, точно следуя описанным выше шагам.
2. Затем замените макрос на этот:

Sub InsertBreakOnEachPage()
  Dim nTotalPageNumber As Integer
 
  For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Collapse wdCollapseEnd
    Selection.InsertBreak Type:=wdSectionBreakContinuous
  Next
End Sub

Этот макрос вставляет разрыв раздела в конце каждой страницы текущего документа.

Способ 3: вставьте разрыв раздела на каждой странице нескольких документов

1. Для начала поставьте все tarполучить документы в той же папке.
2. Затем аналогичным образом установите и запустите макрос с соответствующими инструкциями.
3. На этот раз используйте эти коды:

Sub InsertBreaksIntoMultiDoc()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nTotalPageNumber As Integer
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "No folder is selected! Please select the target folder."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
      Application.Browser.Target = wdBrowsePage
      ActiveDocument.Bookmarks("\page").Range.Select
      Selection.Collapse wdCollapseEnd
      Selection.InsertBreak Type:=wdSectionBreakContinuous
    Next
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Макрос должен вызвать окно «Обзор». Выберите папку, в которой вы храните документы, и нажмите «ОК».

Процесс займет не более нескольких секунд.

Удобный инструмент для повреждения документов

Очень неприятно иметь дело с поврежденными документами. В таком случае хороший и надежный инструмент, который может помочь восстановить слово документы должны быть в состоянии уменьшить беспокойство много. Поэтому нужно быть предельно осторожным при выборе инструмента для ремонта. Недостаточная полезность может привести к дальнейшему повреждению.

Об авторе:

Вера Чен — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая Восстановление Excel и pdf ремонт программных продуктов. Для получения дополнительной информации посетите www.datanumen.com