3 метода импорта писем из папки Windows в Outlook

Возможно, вы сохранили несколько писем Outlook в папке Windows. Теперь, если вы хотите импортировать их обратно в папку Outlook, как вы можете это сделать? Эта статья научит вас 3 способам.

Как мы все знаем, Outlook предоставляет встроенную опцию «Сохранить как», с помощью которой вы можете сохранять электронные письма в папку Windows. Однако у вас нет возможности повторно добавить экспортированные электронные письма обратно в папку Outlook. Поэтому, если вы хотите импортировать электронные письма Outlook обратно в Outlook, как вы можете это реализовать? Далее мы научим вас 3 методам. Вы можете выбрать любую по своему усмотрению.

Способ 1: перетащите для импорта

1. В самом начале вам необходимо получить доступ к исходной папке Windows, в которой хранятся электронные письма Outlook для импорта в Outlook.
2. Затем запустите приложение Outlook.
3. Затем откройте папку Outlook, в которую вы хотите импортировать электронные письма.
4. Впоследствии вам нужно сузить как окно папки Windows, так и окно Outlook, пока вы не сможете просматривать их тем временем.
5. После этого в папке Windows вы можете выбрать одно из писем Outlook, а затем нажать «Ctrl + A», чтобы выбрать их все.
6. Позже вы можете перетащить выбранные электронные письма в видимую папку Outlook, как показано на следующем снимке экрана:
7. Наконец, вы увидите, что все электронные письма Outlook были импортированы из папки Windows в папку Outlook, как показано на рисунке ниже:

Способ 2: используйте «CreateItemFromTemplate» в VBA

1. To start with, in the main Outlook window, press “Alt + F11” key buttons.
2. Далее вы получите доступ к окну редактора Outlook VBA.
3. Затем скопируйте следующий код VBA в пустой модуль.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Next you can press F5 key button in the current module window to start the macro.
5. После этого вам нужно перейти к исходной папке Windows во всплывающем диалоговом окне.
6. Наконец, после выбора исходной папки все элементы Outlook в этой папке будут импортированы в предопределенную папку Outlook.
7. Примечание. Таким образом, импортированные электронные письма представляют собой новые новые электронные письма, которые вы можете создавать по своему желанию, как показано на следующем снимке экрана:

Способ 3: используйте «OpenSharedItem» в VBA

1. Как и в методе 2, скопируйте следующие коды VBA в другой модуль.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Затем запустите этот макрос, нажав клавишу «F5».
3. Далее выберите исходную папку.
4. В конечном итоге все электронные письма будут импортированы, как показано на рисунке ниже:

Сравнения

Средства для блокировки повреждения данных PST

Как мы все знаем, Outlook поставляется со встроенным инструментом — Скэнпст. Most of time, it is capable of solving small problems. However, if the issues are blazing severe, the built-in tool will tend to fail. So, you had better recur to a more potent tool, such as DataNumen Outlook Repair.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая SQL Server коррупция и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com