2 быстрых способа экспортировать список всех помеченных писем Outlook в Excel

Перспективные решения 29 сентября, 2025
Поделись сейчас:

Если вы хотите экспортировать список всех помеченных писем из почтового ящика Outlook в Excel, вы можете использовать любой из двух методов, описанных в этой статье.

Например, чтобы своевременно обрабатывать все помеченные электронные письма или делиться ими с кем-то еще, вы можете экспортировать их в рабочий лист Excel. Здесь мы представим 2 подхода для его реализации. Первый использует стандартную функцию «Импорт и экспорт» после обнаружения помеченных писем. Честно говоря, немного утомительно. Таким образом, в последнем мы научим вас более удобному способу применения VBA.

Экспорт списка всех помеченных писем Outlook в Excel

Способ 1: вручную экспортировать все найденные помеченные электронные письма

  1. Прежде всего, щелкните в поле поиска над списком рассылки.
  2. Затем нажмите «Все почтовые элементы» в группе «Область действия» на вкладке «Поиск».
  3. Затем нажмите кнопку «Помечено» в группе «Определить».Поиск помеченных писем
  4. После того, как все помеченные электронные письма будут показаны в списке, выберите одно письмо и нажмите «Ctrl + A», чтобы выбрать их все.
  5. Затем нажмите сочетание клавиш «Ctrl + Shift + V».
  6. В новом диалоговом окне создайте новую папку в файле Outlook.Создать новую папку
  7. Позже выберите новую созданную папку и нажмите «ОК», чтобы переместить все найденные помеченные электронные письма в новую папку.Переместите все помеченные электронные письма в новую папку
  8. После этого нажмите «Файл» > «Открыть» > «Импорт»,
  9. Во всплывающем диалоговом окне выберите «Экспорт в файл» > «Далее» > «Microsoft Excel 97-2003» > «Далее».Экспорт в файл
  10. На новом экране выберите нужную папку и нажмите «Далее».Выберите папку для экспорта
  11. Затем следуйте указаниям мастера, чтобы завершить «Экспорт».
  12. Вы получите новый файл Excel, показанный на следующем снимке экрана.Экспортированный файл Excel

Способ 2: экспортировать список всех помеченных писем через VBA

  1. В Outlook нажмите «Alt + F11», чтобы вызвать редактор VBA.
  2. Затем включите «Объект MS Excel» в соответствии с «Как добавить объектную библиотекуrary Ссылка в VBA».
  3. Затем скопируйте приведенный ниже код VBA в модуль.
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

Код VBA - Экспорт списка всех помеченных писем

  1. Наконец, поместите курсор в подпрограмму «ExportAllFlaggedEmailsToExcel» и нажмите кнопку «F5».
  2. Затем выберите файл Outlook в новом диалоговом окне.Выберите файл Outlook
  3. Когда вы получите сообщение «Завершено», вы также получите новый файл Excel, как показано на рисунке ниже.Экспортированный файл Excel через VBA

Защитите свой Outlook от коррупции

Outlook подвержен ошибкам и повреждению, поэтому для нас очень трудная задача защитить наши данные Outlook. Несомненно, мost Эффективным и практичным способом является регулярное резервное копирование данных для Outlook. В дополнение к этому нам также необходимо получить мощный и надежный инструмент исправления Outlook, такой как DataNumen Outlook Repair. Пригодится, если инструмент для ремонта входящих не оказывает никакого влияния.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая фиксировать SQL Server и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com

Поделись сейчас:

Комментарии закрыты.