Cum să exportați în lot mai multe e-mailuri Outlook într-un document Word prin VBA

Dacă doriți să exportați în serie mai multe e-mailuri Outlook într-un singur document Word, puteți utiliza codul VBA prezentat în acest articol. Vă poate ajuta să îndepliniți această sarcină în câteva secunde.

Am introdus vreodată cum să convertesc un e-mail Outlook într-un document Word în articolul meu anterior – „2 Metode eficiente pentru a converti un e-mail Outlook într-un document Word”. Totuși, ambele cele 2 mijloace menționate în acel post va fi neajutorat în cazul în care doriți să exportați în serie multe e-mailuri într-un singur document Word. Prin urmare, aici vă vom învăța un alt mod. Acum, citiți mai departe pentru a o obține în detaliu.

Export în lot mai multe e-mailuri Outlook într-un document Word

1. Pentru a starcu, lansați programul Outlook.
2. Apoi, după ce ați intrat în fereastra principală Outlook, trebuie să apăsați butoanele tastei „Alt + F11”.
3. În continuare, veți avea acces la editorul Outlook VBA, în care ar trebui să deschideți un modul gol.
4. Ulterior, copiați codul VBA de mai jos în fereastra modulului deschisă.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. După aceea, este mai bine să adăugați acest nou proiect VBA la bara de instrumente de acces rapid sau la panglică.
6. În cele din urmă, poți încerca.

• În primul rând, selectați mai multe e-mailuri Outlook.
• Apoi localizați și faceți clic pe butonul macro nou adăugat.
• După ce vi se solicită „Terminat”, puteți naviga la folderul local predefinit pentru a găsi un nou document Word.
• Deschideți acest document, în care puteți vedea că toate e-mailurile selectate au fost exportate.

Păstrați un instrument de recuperare puternic în apropiere

Indiferent de numeroasele funcții, Outlook încă nu poate fi imun la erori. Dacă sunteți obișnuit să lăsați erorile în pace, cu ele adunându-se, blocarea Outlook va avea loc cu siguranță. În acel moment, este esențial să recurgeți la un instrument de recuperare puternic și eficient, cum ar fi DataNumen Outlook Repair. Este bine versat Remediere PST. Atâta timp cât cu el, nu va mai trebui să vă faceți griji cu privire la pierderea datelor Outlook.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv mdf corupt și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com